Mehrere Suchvorgänge

[Jac de Lad]

Vielleicht wäre es noch möglich mehrere Suchvorgänge gleichzeitig zu ermöglichen, also FindFirst$() und FindNext$() mit einem optionalen Parameter auszustatten.

Jac

Hi Jac,

geht doch schon

Proc Callback1
  Var addi$ = ""
  Parameters hwnd&,l&,Find$
  addi$ = FindFirst$(Find$)
  If addi$ <> ""
    Addstring(l&,addi$)
  EndIf
  WhileNot %IOResult
    addi$ = FindNext$(Find$)
    If addi$ <> ""
      Addstring(l&,addi$)
    EndIf
  EndWhile
  End
EndProc

window 600,600
Var ende% = 0
Var Liste& = Create("Listbox",%hwnd,0,10,10,300,300)
Var h1&=PExec("|Callback1",%Hwnd,Liste&,"*.prf")
Var h2&=PExec("|Callback1",%Hwnd,Liste&,"*.txt")
WhileNot ende%
  Waitinput
  ende% = 1
EndWhile
End

[Jac de Lad]

Hallo Unregistriert.

Nein, das ist nicht das was ich meine, da dir Funktionen gleichzeitig ablaufen und nicht miteinander kommunizieren. FindNext$() hat keine Parameter. Und ich meinte, dass ich in zum Beispiel in einer Schleife mit FindFirst$() starte und dann in dieser Schleife zum Beispiel eine neue Schleife aufmache und mit dem Ergebnis der ersten FindFirst$()/FindNext$() ein neues FindFirst$()/FindNext$() starte, welches nach Beendigung dieses Suchlaufs wieder mit dem ersten weitermacht. Deshalb auch ein optoinaler Parameter mit einem Zähler (erster Suchlauf=0, zweiter Suchlauf=1).

Hier mal ein Beispiel wie ich mir das vorstelle:

Proc Suchlauf
declare p$,q$
p$=FindFirst$("C:\\*.*",0)
whilenot p$=""
if DirExists(p$)
q$=FindFirst$(p$+"\\*.*",1)
whilenot q$=""
if FileExists(q$)
AddString(variable&,q$)
endif
q$=FindNext$(1)
endwhile
endif
p$=FindNext$(0)
endwhile
endproc

Der Code ist wie gesagt nur ein Beispiel. Er sucht alle Dateien in der zweiten Ebene von "C:\". Man könnte ihn jetzt noch so gestalten, dass der alle Dateien in allen Unterordnern findet, dazu brauch man nur 2 Funktionen zu schreiben, wo der Zähler in einer Variable verwaltet wird. Aber das Prinzip des von mir gewünschten Zählers sollte jetzt klar sein.

Jac

Hallo Jac,

geht auch.

Proc Callback1
  Var addi$ = ""
  Parameters hwnd&,l&,Find$
  addi$ = FindFirst$(Find$)
  If addi$ <> ""
    Addstring(l&,addi$)
  EndIf
  WhileNot %IOResult
    addi$ = FindNext$(Find$)
    If addi$ <> ""
      Addstring(l&,addi$)
    EndIf
  EndWhile
  End
EndProc

Proc Suchlauf
  Parameters Find$,Find1$,Liste&
  Var h1& = 0
  Var p$ = FindFirst$(Find$)
  p$=Translate$(Translate$(p$,"[",""),"]","")
  Find$=left$(Find$,3)
  whilenot p$=""
    p$=Translate$(Translate$(p$,"[",""),"]","")
    if DirExists(find$+p$)
      h1&=PExec("|Callback1",%Hwnd,Liste&,find$+p$+find1$)
    endif
    p$=FindNext$()
  endwhile
EndProc

window 600,600
Var ende% = 0
Var Liste& = Create("Listbox",%hwnd,0,10,10,300,300)
Suchlauf("D:\\*.*","\\*.Hallihallo",Liste&)
WhileNot ende%
  Waitinput
  ende% = 1
EndWhile
End

[Frabbing]

Mit einem Handle oder einer Nummer wäre es aber einfacher und viel unkomplizierter. Zusätzlich optional würde Einsteiger auch nicht überfordern.

[Jac de Lad]

Hallo Unregistriert.

Klar geht das, ich kann auch auf das Callback warten. Aber es ist meines Erachtens nicht sinnvoll sowas auszulagern und gleich einen neuen Prozess aufzumachen. Das ist etwas umständlich.

Eine andere Möglichkeit ohne optionalen Zähler wäre noch erst zu suchen, das Ergebnis zu speichern und dann erst auszuwerten.

Jac

[Andreas Miethe]

Zitat von Jac de Lad

Hallo Unregistriert.

Klar geht das, ich kann auch auf das Callback warten. Aber es ist meines Erachtens nicht sinnvoll sowas auszulagern und gleich einen neuen Prozess aufzumachen. Das ist etwas umständlich.

Jac

So,bin wieder registriert

Hallo Jac,

und ob das sinnvoll ist sowas auszulagern.
So eine Suche kann unter Umständen lange dauern, und genau so lange ist Dein Programm blockiert.

Sieh mal hier.
Du kannst während der Suche durch die Liste scrollen. Versuch das mal ohne Auslagerung.

'##############################
'Rekursive Suche nach Dateien
'Andreas Miethe 2010
'##############################

$H Windows.ph
$H Messages.ph

Proc GetFilesInDir
  'Rekursive oder einfache Suche nach Dateien
  Parameters Directory$,Maske$,Liste&,Rekursiv%,Text&,Gefunden&

  Struct FILETIME = dwLowDateTime&,\
  dwHighDateTime&

  Struct WIN32_FIND_DATA  = dwFileAttributes&,\
  ftCreationTime.FILETIME!,\
  ftLastAccessTime.FILETIME!,\
  ftLastWriteTime.FILETIME!,\
  nFileSizeHigh&,\
  nFileSizeLow&,\
  dwReserved0&,\
  dwReserved1&,\
  cFileName$(~MAX_PATH),\
  cAlternateFileName$(14)

  Proc Suche
    Parameters Directory$,Maske$,Liste&,Rekursiv%,Text&,Gefunden&
    Var WFD# = New(WIN32_FIND_DATA)
    Var Find1$ = ""
    Var hFind& = 0
    If (Directory$ <> "")  and (Right$(Directory$,1) <> "\\")
      Directory$ = Directory$+"\\"
    EndIf
    Var Find$ = Directory$+Maske$

    hFind& = ~FindFirstFile(Find$,WFD#)
    If hFind& <> 0
      Settext Text&,Directory$
      Repeat
        If (Trim$(WFD#.cFileName$) <> ".") and (Trim$(WFD#.cFileName$) <> "..") and ((WFD#.dwFileAttributes& & ~FILE_ATTRIBUTE_DIRECTORY) <> ~FILE_ATTRIBUTE_DIRECTORY)
          If Trim$(WFD#.cFileName$) <> ""
            AddString(Liste&,Directory$+Trim$(WFD#.cFileName$))
            Settext Gefunden&,Str$(GetCount(Liste&))
          EndIf
        EndIf
      Until ~FindNextFile(hFind&,WFD#) = 0
      ~FindClose(hFind&)
    Else
    EndIf

    If Rekursiv% = 1
      Find1$ = Directory$+"*.*"
      hFind& = ~FindFirstFile(Find1$,WFD#)
      Repeat
        If (Trim$(WFD#.cFileName$) <> ".") and (Trim$(WFD#.cFileName$) <> "..") and ((WFD#.dwFileAttributes& & ~FILE_ATTRIBUTE_DIRECTORY) = ~FILE_ATTRIBUTE_DIRECTORY)
          '#########################################
          'Hier ruft sich die Procedur selbst auf !!
          '#########################################
          Suche(Directory$+Trim$(WFD#.cFileName$),Maske$,Liste&,1,Text&,Gefunden&)
        EndIf
      Until ~FindNextFile(hFind&,WFD#) = 0
      ~FindClose(hFind&)
      Dispose WFD#
    EndIf

  EndProc

  Var Ende& = 0
  WhileNot ende&
    Suche(Directory$,Maske$,Liste&,Rekursiv%,Text&,Gefunden&)
    Ende& = 1
  EndWhile
  Settext Gefunden&,"Suche beendet :" + Str$(GetCount(Liste&)) + " Dateien gefunden die dem Suchkriterium entsprechen"
  End
EndProc


Declare Ende&
Windowstyle 512+24
window %maxx,%maxy
CLS ~GetSysColor(~Color_BTNFACE)
WindowTitle "Rekursion"
SetDialogFont ~GetStockObject(~DEFAULT_GUI_FONT)
Var Text& = Create("TEXT",%hwnd,"",0,0,width(%hwnd),24)
Var Gefunden& = Create("TEXT",%hwnd,"",0,28,width(%hwnd),24)
Var Liste& = Create("Listbox",%hwnd,0,0,100,width(%hwnd),height(%hwnd)-100)
Var P& = 0
Var IsOpen& = 1
Var h1&=PExec("|GetFilesInDir","C:\\","*.prf",Liste&,1,text&,Gefunden&)',%Hwnd,Liste&,find$+p$+find1$,2)

WhileNot Ende&
  Waitinput
  If %key = 2
    process("Kill", h1&,0)
    Ende& = 1
  EndIf
EndWhile
End

[p. specht]

Issja wie Weihnachten! Danke!

[Jac de Lad]

Ah danke, so gehts natürlich auch. Allerdings will ich nicht immer, dass man währenddessen in der Liste scrollen kann, aber das kann man natürlich sehr einfach blockieren.

Jac