Informations-Fenster der anderen Art.

[horsthorn]

Habe mir aus Bruchstücken aus der "XProfan-Welt" ein Info-Fenster (Abouth) gebastelt. Funktioniert sehr gut. Wer es brauchen kann, bitte sehr...
Codetect wurde nach dem "Meckern" von Jörg geändert...

PROC ZOOM_FENSTER
PARAMETERS zoom_copy$,programm$,vers$,zoom_gross%,zoom_zweck$,zoom_status$
Case zoom_gross% > 60:zoom_gross% = 60 'Schriftgröße maximal 60 Pixel
DECLARE G_1%,XX%,YY%,PosXX%,PosYY%,Xeff%,Yeff%,LXX%,LYY%,txt1%
DECLARE zoom_win&,zoom_end&,zoom_end%,zoom_font0%
DECLARE autor&,profan&,listview&
DECLARE autor$,profan$,listview$
'----------------------------------------------------------------------
autor$="Homepage des Programm-Autors" 'hier muss die eigene Adresse stehen
'----------------------------------------------------------------------
profan$="http://xprofan.de/start.htm" 'Existiert
listview$="http://www.frabbing.bplaced.net" 'EXistiert
zoom_font0%=CREATE("FONT","ARIAL",16,6,0,0,0)
zoom_end%=0
XX% = 500 'kann geändert werden
YY% = 420 'kann geändert werden
PosXX% = (%Maxx/2)-(XX%/2)
PosYY% = (%Maxy/2)-(YY%/2)
Windowstyle 1
zoom_win&=CREATE("WINDOW",%hwnd,"Über...",0,0,0,0)
Whileloop 1,100
   Sleep 1 
   Inc G_1%
   Xeff% = XX%*G_1%/100
   Yeff% = YY%*G_1%/100
   LXX% = (%Maxx/2)-(Xeff%/2)
   LYY% = (%Maxy/2)-(Yeff%/2)
   Setwindowpos zoom_win& = LXX%,LYY% - Xeff%,Yeff%;0
Endwhile
ZOOM_TITELBILD
WHILENOT zoom_end%
            Waitinput
CASE %WMPAINT:ZOOM_TITELBILD
IF GETFOCUS(zoom_end&)           
Whilenot G_1% = 1
   Sleep 1 
   Dec G_1%
   Xeff% = XX%*G_1%/100
   Yeff% = YY%*G_1%/100
   LXX% = (%Maxx/2)-(Xeff%/2)
   LYY% = (%Maxy/2)-(Yeff%/2)
   Setwindowpos zoom_win& = LXX%,LYY% - Xeff%,Yeff%;0
Endwhile
zoom_end%=1
DESTROYWINDOW(zoom_win&)
SETFOCUS(%HWnd)
ENDIF
CASE GETFOCUS(autor&):ShellExec(autor$,"open",3)        
CASE GETFOCUS(profan&):ShellExec(profan$,"open",3)                
IF zoom_status$ > "0"      
        CASE GETFOCUS(listview&):ShellExec(listview$,"open",3)                
ENDIF
ENDWHILE
'---------------------------------
PROC ZOOM_TITELBILD
STARTPAINT zoom_win&
USEFONT "ARIAL",zoom_gross%,0,1,1,0
TEXTCOLOR RGB(130,130,130),-1
DrawText 22,15,programm$+" "+vers$
TEXTCOLOR RGB(0,0,255),-1
DrawText 20,11,programm$+" "+vers$
txt1%=CREATE("TEXT",zoom_win&,zoom_copy$,40,73,XX%,20)
setFont txt1%,zoom_font0%
txt1%=CREATE("TEXT",zoom_win&,zoom_zweck$ ,40,95,XX%,20)
SetFont txt1%,zoom_font0%
TEXTCOLOR RGB(0,0,0),-1
USEFONT "ARIAL",16,0,0,1,0
DrawText 30,262,"Hier das Übliche, das ein Autor schreiben muss..."
TEXTCOLOR RGB(0,0,250),-1
DrawText 130,117,"Die Homepage des Programm-Autors..."
DrawText 130,162,"Programm-Code in   XPROFAN - "+$ProfVer
'--------------------------------------------------------------
'Icon-Anzeige entweder aus einer DLL-Datei oder
DrawIcon "SHELL32.DLL", 13, 50, 165
'eines der XProfan-eigenen Icons.
'CREATE("ICON",zoom_win&,"A",50,165) 
'---------------------------------------------------------------
CASE zoom_status$ > "0":DrawText 130,207,"Die hier intregierte  LISTVIEW.DLL..."
USEFONT "ARIAL",16,0,1,1,0
DrawText 30,280,"Das Programm wurde von mehreren Nutzern eingehend getestet... " 
DrawText 30,295,"Trotzdem lehnt der Autor die Haftung für eventuelle Datenverluste "
DrawText 30,310,"oder Schäden am System ab."
DrawText 30,330,"Viel Erfolg und Spass mit  "+UPPER$(programm$)+" "+vers$
ENDPAINT
autor&=CREATE("BUTTON",zoom_win&,autor$,120,132,300,25)
SetFont autor&,zoom_font0%
profan&=CREATE("BUTTON",zoom_win&,"Entwickler:   Roland G. HÜLSMANN",120,177,300,25)
SetFont profan&,zoom_font0%
IF zoom_status$ > "0"
listview&=CREATE("BUTTON",zoom_win&,"...stammt von   Frank ABBING",120,222,300,25)
SetFont listview&,zoom_font0%
ELSE
VAR zoom_txt%=CREATE("TEXT",zoom_win&,dt("getDate",2),130,225,300,20)
SetFont zoom_txt%,zoom_font0%
ENDIF
zoom_end&=CREATE("BUTTON",zoom_win&,"Schließen",360,350,100,25)
SetFont zoom_end&,zoom_font0%
ENDPROC
ENDPROC

'Parameters:
'1. Copyright-Vermerk
'2. Programm-Name
'3. Version
'4. Schriftgrösse des Titels - maximal 60
'5. Kurzbeschreibung
'6. Listview-Info - bei 1 oder größer wird der Button zur Website von Frank Abbing angezeigt

zoom_fenster "copyright by Programm-Autor H. Mustermann ©2011","Beispiel-Test","1.00",60,\
"Hier kann eine Kurzbeschreibung des Programmes stehen...","1"

[Frabbing]

Sehr nett!

[p. specht]

MegaAffenGeil! Superst! Geradezu Hyperdrüber - einfach weil das jeder Programmierer braucht!

[_Joerg_]

Hallo Horst,

ist wirklich Klasse! Kleiner Schönheitsfehler ist noch, daß die ganzen Drawtext-Sachen verschwinden, wenn ein anderes Fenster drüber liegt, und daß das Textfeld für den Autor in diesem Fall zu klein ist... ach ja: WindowStyle - das Fenster kann man noch mit der Maus vergrößern.
Aber die Idee mit dem Zoom ist nett.

Gruß
Jörg

[horsthorn]

@Jörg
Das Fenster hab ich ja mit diesen Maßen für mich geschrieben.
Vergrößern kannst du die Startmasse:

XX% = dein Maß
YY% = dein Maß

Normal liegt über dem Info-Fenster kein anderes Fenster.
Wenn doch, kannst du das doch mit %WMPaint abfangen.
Du bist doch selbst ein Experte oder ?

[_Joerg_]

Ich hab das mal aus Anwendersicht geschrieben. Wenn Du das so in Deinem Programm hast, wird der Nutzer staunen, wenn er den Dialog aufruft und dann evtl. mal den Explorer und alle Texte sind weg. Außerdem macht es einen wnig professionellen Eindruck, wenn man so ein Infofenster nachträglich noch in der Größe verändern kann.

[horsthorn]

@Jög
Hast Recht und ich habe den Code jetzt geändert. %WmPaint ist drin
und das Fenster kann nicht verändert werden - OK ?

[p. specht]

Klasse! Mit Sleep 8 statt Sleep 1 an 2 Stellen kommt´s bei mir sogar noch eleganter!

[Volkmar]

Sieht super aus und mit der Änderung ist das fast OK. Es werden noch beim Neumalen alle Controls neu erzeugt und die Variable zoom_txt% neu angelegt. Alles, was Create und Var enthält, darf bei %wmPaint nicht ausgeführt werden.

Gruß Volkmar

[p. specht]

Zwischenfrage: Wie kann ich ein einfaches anklickbares Link OHNE Button auf ein Hauptfenster bekommen? Irgendwie stehe ich momentan sowas von auf der Leitung...

[Volkmar]

Auf die Schnelle fällt mir da @Mouse() ein

Gruß Volkmar

[Frabbing]

Zitat von p. specht

Zwischenfrage: Wie kann ich ein einfaches anklickbares Link OHNE Button auf ein Hauptfenster bekommen? Irgendwie stehe ich momentan sowas von auf der Leitung...

Probier das mal: Hyperlink / Syslink Control

[AHT]

'#####################################################################################
'#########                          Code von AHT                             #########
'#########      Gepostet für http://www.paules-pc-forum.de                   #########
'#####################################################################################
Def InitCommonControlsEx(1) !"COMCTL32","InitCommonControlsEx"
Def GetLastError(0) !"Kernel32","GetLastError"
Def ShellExecute(7) !"Shell32","ShellExecute"
DEF CopyMemory(3) !"kernel32","RtlMoveMemory"
DEF WideCharToMultiByte(8) !"kernel32","WideCharToMultiByte"
Def ReadProcessMemory(5) !"kernel32","ReadProcessMemory"
Def GetCurrentProcess(0) !"kernel32","GetCurrentProcess"
$H Windows.PH
Declare SysLink&, INITC#, Link$, Operation$, LinkStructures#, LITEM#, LITEM&, UW&, UL&, read&
Declare NMHDR&
Windowstyle 31+512
WindowTitle "Syslink Control"
Window 0,0-640,440
DIM INITC#,8
long INITC#,0=8
long INITC#,4=$8000
@InitCommonControlsEx(INITC#)
Dispose INITC#
Let Link$="  Das ist ein <A HREF="+Chr$(34)+"http://www.web-treffpunkt.de/"+Chr$(34)+">geiles Programm</A>!"
SysLink&=@Control("Syslink",Link$,~WS_VISIBLE | ~WS_CHILD | ~WS_TABSTOP | ~WS_BORDER,20,20,210,25,%HWND,5508,%HINSTANCE,$10000 | $1 | $40000)
Usermessages $10
While %UMESSAGE<>$10
 Waitinput
 IF %WMNOTIFY
  IF &NotifyWnd=SysLink&
   IF %NotifyCode=-2
    ShellExec("http://www.web-treffpunkt.de/","open",1)
   endif
  endif
 endif
EndWhile

[p. specht]

WOW .. Danke !

Edit: Control("Syslink" schreibt mir unter Win7-64/XProfan11.2a den vollen HTML-Ausdruck samt Klammern als Text hin. Vielleicht fehlt ja nur irgend eine Berechtigung. Muss mich mal näher mit SysLink bei MSDN befassen.

[horsthorn]

@Volkmar

Sieht super aus und mit der Änderung ist das fast OK. Es werden noch beim Neumalen alle Controls neu erzeugt und die Variable zoom_txt% neu angelegt. Alles, was Create und Var enthält, darf bei %wmPaint nicht ausgeführt werden.

Du hast natürlich Recht. Das war ein dicker Fehler von mir !
Habe jetzt die Buttons und das Create("Text"... aus dem StartPaint rausgenommen. Denke mal, daß jetzt alles stimmt.

PROC ZOOM_FENSTER
PARAMETERS zoom_copy$,programm$,vers$,zoom_gross%,zoom_zweck$,zoom_status$
Case zoom_gross% > 60:zoom_gross% = 60 'Schriftgröße maximal 60 Pixel
DECLARE G_1%,XX%,YY%,PosXX%,PosYY%,Xeff%,Yeff%,LXX%,LYY%,txt1%
DECLARE zoom_win&,zoom_end&,zoom_end%,zoom_font0%
DECLARE autor&,profan&,listview&
DECLARE autor$,profan$,listview$
'----------------------------------------------------------------------
autor$="Homepage des Programm-Autors" 'hier muss die eigene Adresse stehen
'----------------------------------------------------------------------
profan$="http://xprofan.de/start.htm" 'Existiert
listview$="http://www.frabbing.bplaced.net" 'EXistiert
zoom_font0%=CREATE("FONT","ARIAL",16,6,0,0,0)
zoom_end%=0
XX% = 500 'kann geändert werden
YY% = 400 'kann geändert werden
PosXX% = (%Maxx/2)-(XX%/2)
PosYY% = (%Maxy/2)-(YY%/2)
Windowstyle 1
zoom_win&=CREATE("WINDOW",%hwnd,"Über...",0,0,0,0)
Whileloop 1,100
   Sleep 2
   Inc G_1%
   Xeff% = XX%*G_1%/100
   Yeff% = YY%*G_1%/100
   LXX% = (%Maxx/2)-(Xeff%/2)
   LYY% = (%Maxy/2)-(Yeff%/2)
   Setwindowpos zoom_win& = LXX%,LYY% - Xeff%,Yeff%;0
Endwhile
'-----------------------------------------------------------------
autor&=CREATE("BUTTON",zoom_win&,autor$,120,132,300,25)
SetFont autor&,zoom_font0%
        profan&=CREATE("BUTTON",zoom_win&,"Entwickler:   Roland G. HÜLSMANN",120,177,300,25)
        SetFont profan&,zoom_font0%
IF zoom_status$ > "0"
        listview&=CREATE("BUTTON",zoom_win&,"...stammt von   Frank ABBING",120,222,300,25)
        SetFont listview&,zoom_font0%
ELSE
        VAR zoom_txt%=CREATE("TEXT",zoom_win&,dt("getDate",2),130,225,300,20)
        SetFont zoom_txt%,zoom_font0%
ENDIF
        zoom_end&=CREATE("BUTTON",zoom_win&,"Schließen",390,345,100,25)
        SetFont zoom_end&,zoom_font0%
'-------------------------------------------------------------------        
ZOOM_TITELBILD

WHILENOT zoom_end%
            Waitinput
CASE %WMPAINT:ZOOM_TITELBILD
CASE CLICKED(autor&):ShellExec(autor$,"open",3)        
CASE CLICKED(profan&):ShellExec(profan$,"open",3)  
IF zoom_status$ < "1"                   
        EnableWindow listview&,0
ELSE        
        CASE CLICKED(listview&):ShellExec(listview$,"open",3)                
ENDIF
IF CLICKED(zoom_end&)           
Whilenot G_1% = 1
   Sleep 1 
   Dec G_1%
   Xeff% = XX%*G_1%/100
   Yeff% = YY%*G_1%/100
   LXX% = (%Maxx/2)-(Xeff%/2)
   LYY% = (%Maxy/2)-(Yeff%/2)
   Setwindowpos zoom_win& = LXX%,LYY% - Xeff%,Yeff%;0
Endwhile
zoom_end%=1
DESTROYWINDOW(zoom_win&)
SETFOCUS(%HWnd)
ENDIF
ENDWHILE
'---------------------------------
PROC ZOOM_TITELBILD
STARTPAINT zoom_win&
USEFONT "ARIAL",zoom_gross%,0,1,1,0
TEXTCOLOR RGB(130,130,130),-1
DrawText 22,15,programm$+" "+vers$
TEXTCOLOR RGB(0,0,255),-1
DrawText 20,11,programm$+" "+vers$
TEXTCOLOR RGB(0,0,0),-1
USEFONT "ARIAL",16,0,0,1,0
DrawText 40,73,zoom_copy$
DrawText 40,95,zoom_zweck$
DrawText 30,260,"Hier das Übliche, das ein Autor schreiben muss..."
TEXTCOLOR RGB(0,0,250),-1
DrawText 130,117,"Die Homepage des Programm-Autors..."
DrawText 130,162,"Programm-Code in   XPROFAN - "+$ProfVer
'--------------------------------------------------------------
'Icon-Anzeige entweder aus einer DLL-Datei oder
DrawIcon "SHELL32.DLL", 13, 50, 165
'eines der XProfan-eigenen Icons.
'CREATE("ICON",zoom_win&,"A",50,165) 
'---------------------------------------------------------------
CASE zoom_status$ > "0":DrawText 130,207,"Die hier intregierte  LISTVIEW.DLL..."
USEFONT "ARIAL",16,0,1,1,0
DrawText 30,280,"Das Programm wurde von mehreren Nutzern eingehend getestet... " 
DrawText 30,295,"Trotzdem lehnt der Autor die Haftung für eventuelle Datenverluste "
DrawText 30,310,"oder Schäden am System ab."
DrawText 30,330,"Viel Erfolg und Spass mit  "+UPPER$(programm$)+" "+vers$
ENDPAINT
ENDPROC
ENDPROC

'Parameters:
'1. Copyright-Vermerk
'2. Programm-Name
'3. Version
'4. Schriftgrösse des Titels - maximal 60
'5. Kurzbeschreibung
'6. Listview-Info - bei 1 oder größer wird der Button zur Website von Frank Abbing angezeigt

zoom_fenster "copyright by Programm-Autor H. Mustermann ©2011","Beispiel-Test","1.00",60,\
"Hier kann eine Kurzbeschreibung des Programmes stehen...","1"