Icon im Trackmenu

[horsthorn]

Wer von den XProfanern kann mir ein Codeschnipsel überlassen, mit dem ich Programmicons in ein Trackmenu zeichnen kann? - Das Tool QUICKSTART von mir erzeugt im Hauptfenster nach der Auswahl eines Programmes immer das Programm-Icon. Das hätte ich gerne auch im Trackmenu.
Also nicht schüchtern sein, sondern dem "alten Mann" Horst helfen !

PS:
QUICKSTART steht auf meiner HP zum Download bereit

[Frabbing]

Soweit ich weiss, erwarten Menüs ein Bitmaphandle. Iconhandles werden IMHO nicht unterstützt.
Du kannst natürlich Icons in Bitmaps umwandeln und dann mit SetMenuItemBitmaps für einen Menüeintrag einblenden.
Oder du zeichnest Menüs sofort ownerdrawn. Mein Tool Hardcopy z.B. nutzt eine tolle Assembler-Library dafür. Wenn ich mal wieder Zeit und Lust habe, könnte ich einige Dll-Funktionen mithilfe der Library in eine Dll bündeln. Dann kann sie auch direkt mit XProfan benutzt werden, ohne XPIA verwenden zu müssen.

[horsthorn]

@Frank
Du kennst mich doch
Die einzige DLL, die ich akzeptiere ist die LISTVIEW.DLL -
Ansonsten will ich doch alles mit XProfan-Mitteln machen

[Jac de Lad]

Das geht per API. Das Beispiel macht das mit dem normalen Menü; für das Trackmenu musst du nochmal im MSDN nachschlagen (der generelle Aufruf sollte aber gleich sein).

Das Beispiel stammt von Sebastian König.

[Frabbing]

Jac, er möchte Icons als Menubilder, keine Bitmaps. Direkt Icons einsetzen geht meine ich nicht.
Aber man kann Icons einladen, bzw. kopieren und als Bitmaphandle an die API übergeben. Notfalls über die Speicherbitmap, eleganter aber über einen DC.

[Jac de Lad]

Icon oder Bitmap ist doch Wurscht. Da muss er's halt als Bitmap beilegen.

[horsthorn]

@Jac
Ist eben nicht "wurscht" ! - Im Tool 'QUICKSTART' werden frei zu wählende Programme auf einem Hauptfenster mit ihrem Icon angezeigt und können von da auch gestartet werden. Ähnlich den Icon auf dem Desctop -
Dieses Fenster kann zum Trayicon minimiert werden und mit der rechten Mausraste werden hier ebenfalls die gewählten Programme gezeigt und mit der linken Taste gestartet. Soweit ist alles im "grünen Bereich" und steht zum Download bereit. In einer moderneren Version möchte ich aber, dass die Programme im Trackmenu des Trayicon ebenfalls als Icon erscheinen und zwar im Format 16x16 - "Capiste" ? - Erschwerend kommt noch dazu, dass ich möglichst ohne eine Zusatzdatei arbeiten will (DLL öder Ä.)

PS: Lade Dir doch das Tool runter und starte es. Dann siehst Du, was ich meine

[RGH]

Hallo,

was Dir noch fehlt, ist eine Routine um aus einem IconHandle eine Bitmap zu machen:

Proc Ico2Bmp
  Parameters Icon&
  ' Weiße Bitmap in Größe 32 * 32 erzeugen
  Var IBmp& = Create("hNewPic", 32, 32, RGB(255,255,255))
  ' Auf diese Bitmap das Icon zeichnen
  StartPaint IBmp&
    DrawIcon Icon&, 0, 0
  EndPaint
  Return IBmp&
EndProc

Achtung: Die Bitmap hat natürlich die Größe eines Icons (32 * 32), was für eine Menübitmap meist zu groß ist. Bei meinem XP ist selbst 16 * 16 noch zu groß. Daher eine universellere Routine, die aus einem 32 * 32 Icon eine beliebig große (pardon: kleine) Bitmap erzeugt:

Proc Ico2SizedBmp
  Parameters Icon&, dx&, dy&
  ' Weiße temporäre Bitmap in Größe 32 * 32 erzeugen
  Var TempBmp& = Create("hNewPic", 32, 32, RGB(255,255,255))
  ' Auf diese Bitmap das Icon zeichnen
  StartPaint TempBmp&
    DrawIcon Icon&, 0, 0
  EndPaint
  ' Weiße Bitmap in Größe dx& * dy& erzeugen
  Var IBmp& = Create("hNewPic", dx&, dy&, RGB(255,255,255))
  ' Auf diese Bitmap die temporäre Bitmap verkleinert zeichnen
  StartPaint IBmp&
    DrawSizedPic TempBmp&, 0, 0 - dx&, dy&; 0
  EndPaint
  ' Temporäre Bitmap löschen
  DeleteObject TempBmp&
  Return IBmp&
EndProc

Gruß
Roland

[RGH]

Und hier für alle Mitleser, die wissen wollen, wie man überhaupt Anwendungen für den Systemtray von Windows in XProfan programmiert, ein komplettes Beispiellisting mit TrayIcon-Menü und Bildern in demselben:

Declare Hicon&,Ende%,Show%
Declare Checkmerker%,Menuhandle&
Declare hbmChecked&,hbmUnchecked&

DEF SetMenuItemBitmaps(5) !"USER32","SetMenuItemBitmaps"

Proc Ico2SizedBmp
  Parameters Icon&, dx&, dy&
  ' Weiße temporäre Bitmap in Größe 32 * 32 erzeugen
  Var TempBmp& = Create("hNewPic", 32, 32, RGB(255,255,255))
  ' Auf diese Bitmap das Icon zeichnen
  StartPaint TempBmp&
    DrawIcon Icon&, 0, 0
  EndPaint
  ' Weiße Bitmap in Größe dx& * dy& erzeugen
  Var IBmp& = Create("hNewPic", dx&, dy&, RGB(255,255,255))
  ' Auf diese Bitmap die temporäre Bitmap verkleinert zeichnen
  StartPaint IBmp&
    DrawSizedPic TempBmp&, 0, 0 - dx&, dy&; 0
  EndPaint
  DeleteObject TempBmp&
  Return IBmp&
EndProc

Proc Menue
   CreateMenu
   AppendMenu 101, "&Info"
   AppendMenu 102, "&deaktiviert"
   SetMenuItemBitmaps(&hMenu,102,$10,hbmChecked&,hbmUnChecked&)  'Menu-Grafik ändern...
   AppendMenu 106, "Hauptfenster &sichtbar"
   SetMenuItemBitmaps(&hMenu,106,$10,hbmChecked&,hbmUnChecked&)  'Menu-Grafik ändern...
   AppendMenu 104, "-"
   AppendMenu 103, "&Beenden"
   CheckMenu 106, Show%
   CheckMenu 102, Checkmerker%
   Return @TrackMenu()
EndProc  

Windowstyle 26 + 512
WindowTitle "TrayIcon_Test"
Window 0,0-640,480

@ShowWindow(%hWnd,0)

Hicon&        = @create("hIcon","Profan")
hbmChecked&   = Ico2SizedBmp(@create("hIcon", "A"),13,13)
hbmUnChecked& = Ico2SizedBmp(@create("hIcon", "Baum"),13,13)

@TrayIcon("Add", %hWnd, 1, hIcon&, "TrayIcon 11")

Whilenot Ende%
   Waitinput
   If @TrayIcon("Msg", 1) = $203 'Doppelklick links
     Ende%=1
   Elseif @TrayIcon("Msg", 1) = $204 'Rechter Mausbutton gedrückt
     @SetActiveWindow(%hWnd)
     Menue()
     If (%MenuItem = 102)
       Checkmerker% = @Not(Checkmerker%) 'Zustandsänderung merken...
       If Checkmerker% = 0
         Hicon& = @create("hIcon", "A")
         @TrayIcon("SetIcon", %hWnd, 1, hIcon&)
       Else
         Hicon& = @create("hIcon", "Baum")
         @TrayIcon("SetIcon", %hWnd, 1, hIcon&)
       EndIf
       Setmenuitem 0
     ElseIf (%MenuItem = 101)
       @Messagebox("Programmiert in XProfan 11","Hinweis",64)
       Setmenuitem 0
     ElseIf (%MenuItem = 103)
       Ende%=1
     ElseIf (%MenuItem = 106)
       Show% = @Not(Show%)
       @Showwindow(%hWnd,Show%)
       Setmenuitem 0
     EndIf
   Endif
Endwhile

@TrayIcon("Delete", %hWnd, 1)
End

Gruß
Roland

[horsthorn]

@RGH

Danke - das ist doch schon mal ein Anfang

[PaRaDoX-Vision]

Wo wir mal wieder beim Thema wären:
Bei dieser Lösung invertieren die kleinen BMP Bildchen.

Und es wäre sehr schön wenn in XProfan12 sowas schon eingebaut wäre.

Gruß

[Frabbing]

Ha! Eine XProfaner-Seite, die ich bislang noch gar nicht kannte... hello Mr. Paradox.

[Uwe 'Pascal']

Hallo erstmal

Bei dieser Lösung invertieren die kleinen BMP Bildchen.

Das ist von MS so vorgesehen, auch wenn Windows selbst kaum Gebrauch davon macht. Alternative: OWNERDRAW-Menüs

window 1,1-400,400
$H Messages.ph
$H Windows.ph
usermessages 16
proc MenuProc'-----------------------------------------------MenuProc
parameters wnd&,msg&,wparam&,lparam&
if msg&=~WM_MEASUREITEM
   Mes#=lparam&
   Mes#.CtlType&=~ODT_MENU
   Mes#.itemWidth&=150'----Gesamtbreite
   Mes#.itemHeight&=18'----Höhe
elseif msg&=~WM_DRAWITEM
   Draw#=lparam&
 with Draw#
      if .itemState& & ~ODS_SELECTED
         ~SetTextColor(.hDC&,~GetSysColor(~COLOR_HIGHLIGHTTEXT))
         ~SetBkColor(.hDC&,~GetSysColor(~COLOR_HIGHLIGHT))
      else
         ~SetTextColor(.hDC&,~GetSysColor(~COLOR_MENUTEXT))
         ~SetBkColor(.hDC&,~GetSysColor(~COLOR_MENU))
      endif
      var Text$=Text$[.itemData&]
      var Icon&=Icon&[.itemData&]
      ~ExtTextOut(.hDC&,.x1&+20,.y1&,~ETO_OPAQUE,Draw#+28,addr(Text$),len(Text$),0)
      ~DrawIconEx(.hDC&,0,.y1&,Icon&,16,16,0,0,~DI_NORMAL)
 endwith
endif
return ~CallWindowProc(WndProcOld&,wnd&,msg&,wparam&,lparam&)
endproc'-------------------------------------------------------------
proc AppendOwnerDrawMenu'-------------------------AppendOwnerDrawMenu
parameters Menu&,ID%
clear Menu#
Menu#.cbSize&=44
Menu#.fType&=~MFT_OWNERDRAW
Menu#.dwItemData&=ID%
Menu#.fMask&=~MIIM_TYPE | ~MIIM_ID | ~MIIM_DATA
Menu#.wID&=ID%
~InsertMenuItem(Menu&,99,0,Menu#)
endproc'-------------------------------------------------------------
proc PopupOwnerDrawMenu'---------------------------PopupOwnerDrawMenu
parameters Menu&,dlg&,x%,y%
long Pos#,0=x%
long Pos#,4=y%
~ClientToScreen(dlg&,Pos#)
set("Fastmode",1)
~SetWindowLong(%hwnd,~GWL_WNDPROC,WndProcNew&)
~TrackPopupMenu(Menu&,0,long(Pos#,0),long(Pos#,4),0,%hwnd,0)
~SetWindowLong(%hwnd,~GWL_WNDPROC,WndProcOld&)
set("Fastmode",0)
endproc'-------------------------------------------------------------
proc InitOwnerDrawMenu'-----------------------------InitOwnerDrawMenu
struct Mes=CtlType&,CtlID&,itemID&,itemWidth&,itemHeight&,itemData&
dim Mes#,Mes'--MEASUREITEMSTRUCT
struct Draw=CtlType&,CtlID&,itemID&,itemAction&,itemState&,hwndItem&,hDC&,\
            x1&,y1&,x2&,y2&,itemData&
dim Draw#,Draw'--DRAWITEMSTRUCT
struct Menu=cbSize&,fMask&,fType&,fState&,wID&,hSubMenu&,hbmpChecked&,hbmpUnchecked&,\
            dwItemData&,dwTypeData&,cch&,Text$(100)
dim Menu#,Menu'--MENUINFO
dim Pos#,8
WndProcOld&=~GetWindowLong(%hwnd,~GWL_WNDPROC)
WndProcNew&=procaddr(MenuProc,4)
endproc'-------------------------------------------------------------
 
declare Mes#,Draw#,Menu#,Pos#,WndProcOld&,WndProcNew&
declare Text$[3],Icon&[3]
Text$[1]="Hallo Leute"
Text$[2]="Ein Eintrag"
Text$[3]="Noch'n Eintrag"
Icon&[1]=~LoadIcon(0,32513)
Icon&[2]=~LoadIcon(0,32514)
Icon&[3]=~LoadIcon(0,32515)
InitOwnerDrawMenu
var Menu&=~CreatePopupMenu()
AppendOwnerDrawMenu Menu&,1
AppendOwnerDrawMenu Menu&,2
AppendOwnerDrawMenu Menu&,3
while 1
   waitinput
 case %umessage=16:break
 if %mousekey=2
  PopupOwnerDrawMenu(Menu&,%hwnd,%mousex,%mousey)
  print %menuitem
 endif
endwhile
'---Hier bei Bedarf Bereiche und Icons freigeben

Aufwendig, aber sehr vielseitig
Allerdings noch für XProfan10 entwickelt, darum das "gefährliche" ProcAddr()
(Sorry, iF)

Und es wäre sehr schön wenn in XProfan12 sowas schon eingebaut wäre.

Das würde (wieder mal) nur auf einen Kompromiss hinauslaufen; um alle Möglichkeiten nutzen zu können (ob Menü, TreeView, Tab usw.) kommt man um die Grundlagen nicht herum.
So gesehen waren 90 % der Erweiterungen in Profan in den letzten Jahren eigentlich überflüssig

SeeYou
Pascal

[Frabbing]

Hi Pascal,

toll dich hier zu lesen!

Das würde (wieder mal) nur auf einen Kompromiss hinauslaufen; um alle Möglichkeiten nutzen zu können (ob Menü, TreeView, Tab usw.) kommt man um die Grundlagen nicht herum.

Eben, sich etwas Hintergrundwissen anzueignen schadet sowieso nie.
Ich glaube auch nicht, dass es die Aufgabe einer Programmsprache ist, für jedes Control eine Vereinfachung aller möglichen API/Messages anzubieten. Zugegebenermassen ist das aber sehr bequem...

[RGH]

Zitat von Uwe 'Pascal'

... Das würde (wieder mal) nur auf einen Kompromiss hinauslaufen; um alle Möglichkeiten nutzen zu können (ob Menü, TreeView, Tab usw.) kommt man um die Grundlagen nicht herum.
So gesehen waren 90 % der Erweiterungen in Profan in den letzten Jahren eigentlich überflüssig

SeeYou
Pascal

Naja, 90% scheint mir hier recht hoch gegriffen.
Aber du hast sicher recht: ein nicht unerheblicher Teil der Erweiterungen wenden sich an den Einsteiger oder Programmierer, der mit wenigen Zeilen möglichst viel erreichen will, und ermöglichen diesem Kreis mit wenig Aufwand Dinge zu programmieren, die der erfahrende API-Programmierer schon immer konnte, und sei es durch die Verwendung zusätzlicher DLLs!

Zu den Menüs: Natürlich würde man ab XProfan 11 hier das deutlich sicherere Subclassing für Ownerdraw-Menüs benutzen. Oder man geht den Weg, den Norbert Strübli vor ca. 4 Jahren mit seiner XMenu.inc gegangen ist und schreibt sich die Windowsprozedur komplett selbst und verzichtet im Gegenzug auf viele XProfan-Annehmlichkeiten.

Trotzdem könnte natürlich eine in XProfan direkt eingebaute Erweiterung die Geschichte erheblich vereinfachen, so dass man ganz ohne SubClassing (das für den Einsteiger auch einige Fallstricke bietet) oder ProcAddr (das für sowas eigentlich nicht gedacht ist) auskommen könnte. Tatsächlich bastele ich schon seit einer Weile an einer solchen Erweiterung, die z.B. bei den Menübefehlen einen zusätzlichen Parameter, nämlich ein Icon, erlaubt und möglicherweise über Set-Funktionen das Aussehen der Menüs steuert.

Gruß
Roland