Messagebox mit Option

[Andreas Miethe]

Eine kleine Spielerei mit einer Messagebox und einem Hook.
Vielleicht kann's ja jemand gebrauchen .

$H Windows.ph
$H Messages.ph

'#############################
'Messagebox-Konstanten
DEF &IDOK         1
DEF &IDCANCEL     2
DEF &IDABORT      3
DEF &IDRETRY      4
DEF &IDIGNORE     5
DEF &IDYES        6
DEF &IDNO         7
DEF &IDICON      20
DEF &IDPROMPT $FFFF
DEF &IDSTATIC $CAFE
'#############################

Struct CWPSTRUCT = lParam&,wParam&,message&,hwnd&
Struct Rect = left&,top&,right&,bottom&

Declare Hook&,OldProc&
Declare B&,B1&

Proc MB
  Parameters wnd&,msg&,wparam&,lparam&
  Declare Result&
  select msg&
    Caseof ~WM_INITDIALOG
    Var Rect# = New(Rect)
    ~GetWindowRect(wnd&,Rect#)
    ~Movewindow(wnd&,Rect#.left&,rect#.top&,width(wnd&)+12,Height(wnd&)+40,1)
    B& = Create("CheckBox",wnd&,"Diese Meldung nicht wieder anzeigen",0,height(wnd&)-18,width(wnd&),18)
    SendMessage(B&,~WM_SETFONT,~GetStockObject(~ANSI_VAR_FONT),1)
    SendMessage(~GetDlgItem(wnd&,&IDICON),~STM_SETIMAGE,~IMAGE_ICON,~LoadIcon(%hInstance,"EIMER"))
    Result& = 1
    Caseof ~WM_COMMAND
    If lparam& = b&
      If Getcheck(B&)
        B1& = 1
      Endif
    Endif
    Caseof ~WM_NCDESTROY
    ~UnhookWindowsHookEx(Hook&)
    Result& = 1
  Endselect
  Result& = ~CallWindowProc(OldProc&,wnd&,msg&,wparam&,lparam&)
  Return Result&
Endproc

Proc SetHook
  Parameters nCode&, wParam&, lParam&
  Select nCode&
    Caseof ~HC_ACTION
    Var pw# = New(CWPSTRUCT)
    pw# = lparam&
    If pw#.message& = ~WM_INITDIALOG
      OldProc& = ~SetWindowlong(pw#.hwnd&,~GWL_WNDPROC,ProcAddr("MB",4))
    Endif
  EndSelect
  Return ~CallNextHookEx(Hook&, nCode&, wParam&, lParam&)
  EndProc
  
Proc PRF_Messagebox
  Set("Fastmode",1)
  Parameters  body$, title$, flags&
  Declare Result&
  Flags& = Flags& | ~MB_ICONQUESTION
  Hook& = ~SetWindowsHookEx(~WH_CALLWNDPROC, ProcAddr("SetHook",3), 0,~GetCurrentThreadId())
  Result& = MessageBox(title$,body$, flags&)
  Set("Fastmode",0)
  Return Result&
EndProc

cls
Print PRF_Messagebox("Titel","Wirklich löschen ? ",~MB_YESNO)
Print IF(B1&=1,"Nicht wieder anzeigen","wieder anzeigen")
Waitinput

[Jac de Lad]

Auch empfehlen kann ich dir XTaskDlg.dll. Die simuliert TaskDialoge schon ab Windows 98 und hat noch viel mehr Optionen. Ich hab dazu mal ne Inc geschrieben, ist auf meiner Webseite abrufbar.

Jac

[Andreas Miethe]

Zitat von Jac de Lad

Auch empfehlen kann ich dir XTaskDlg.dll. Die simuliert TaskDialoge schon ab Windows 98 und hat noch viel mehr Optionen. Ich hab dazu mal ne Inc geschrieben, ist auf meiner Webseite abrufbar.

Jac

Hallo Jac,

danke für den Hinweis.

Um die Optionen ging es mir allerdings weniger, sondern mehr um die Technik, mit der man solche Dialoge manipulieren kann. Auf diese Art kann ich soviele Optionen reinbringen wie ich will, kann Bilder einfügen, den Hintergund ändern, die Schriftart und Schriftfarbe ändern, usw.usw.

[Frabbing]

Schönes Demo, Andreas! Ich denke, damit inspirierst du sicher den Einen oder Anderen, der sich bisher nicht an Hooks und API gewagt hat.

In dem Zusammenhang möchte ich auf meine AControl.dll hinweisen, die auch einige Systemdialoge hookt. Ist allerdings in Assembler erstellt, weshalb ich da keinen XProfancode posten kann:

[horsthorn]

Habe mir mal vor 2 oder 3 Jahren eine automatisch schließende Messagebox "gebastelt" - Dietmar hat sie sogar in seine Sammlung übernommen - Jawoll

'Messagebox oder Fenster automatisch schließen

'Alle Message-Fenster in PROFAN² müssen immer über einen Button geschlossen werden.
'Es gibt aber auch Meldungen, die nach einer bestimmten Zeit von selbst schliessen.
'Hier ist eine Procedur, die das auch macht. Sollte in jeder Version funktionieren.
'Sogar mein Namensvetter Dietmar Horn hat es in seine Codetext-Sammlung übernommen !
'Horst Horn


PROC ZEIT_FENSTER
DECLARE text_lang%,m_X%,m_txt%,meldung&,m_font&
PARAMETERS m_titel$,icon$,text_B%,m_text$,m_text1$,m_text2$,zeit%,m_back%
'1. Titeltext| 2. Profan-Icon| 3. Fontbreite| 4. Textzeile 1| 5. Textzeile 2| 6. Textzeile 3| 7. Anzeigezeit| 8. Fensterhandle
m_font&=CREATE("FONT","ARIAL",(text_B%*2),text_B%,0,0,0)'Font wird über die Breite erstellt
text_lang%=LEN(m_text$)
m_X%=(text_lang%*text_B%/2+50)'die Breite des Fensters
WindowStyle 48'muss nicht sein...
meldung& = CREATE("WINDOW",%HWnd,m_titel$,(%MaxX/2-m_X%),(%MaxY/2-60),(m_X%*2),130)
CREATE("ICON",meldung&,icon$,10,15)'Alle PROFAN²-Icons sind möglich
m_txt%=CREATE("TEXT",meldung&,m_text$,65,20,(m_X%*2),20)
SetFont m_txt%,m_font&
m_txt%=CREATE("TEXT",meldung&,m_text1$,65,40,(m_X%*2),20)'die 2. und 3. Textzeile sollten
SetFont m_txt%,m_font&
m_txt%=CREATE("TEXT",meldung&,m_text2$,65,60,(m_X%*2),20)'nicht länger wie die 1. sein
SetFont m_txt%,m_font&
'-------------------------
SLEEP zeit%'Anzeigedauer
'-------------------------
DeleteObject m_font&
DesTroyWindow(meldung&)
SetFocus(m_back%)'Der Focus wird auf das Hauptfenster gesetzt
ENDPROC

'Beispiel
CLS
zeit_fenster "Fenster schliesst automatisch","DRUCKER",8,"Der 7. Parameter gibt die Anzeigedauer an",\
"Danach wird das Fenster gelöscht...","Probieren ist angesagt ;o)",2000,%HWnd
waitinput
end

[Frabbing]

Könntest du jetzt mit Andreas Code und einem Timer noch systemkonformer lösen.
Bastel doch mal ein bischen, Horst.

[Jac de Lad]

Ich wollt deine Messagebox ja auch nicht schlecht machen.

[Andreas Miethe]

Zitat von Jac de Lad

Ich wollt deine Messagebox ja auch nicht schlecht machen.

Habe ich auch nicht vermutet