Dauerhafter Hintergrund für Dialogfenster

[Frabbing]

Ein Code für dauerhafte Dialoghintergründe jeglicher Art, also nicht nur einfarbig:

'
' (c) Frabbing für Paules-PC-Forum:
' http://www.paules-pc-forum.de/forum/xprofan/
'
$H windows.ph
$H messages.ph

Declare dc&, ps#

Dim ps#,128

Cls

Proc NeuZeichnen
Parameters thedc&
  StartPaint thedc&
  '
  ' --- Hier den Hintergrund des Dialogs neu zeichnen ---

  UseBrush 1,RGB(128,128,255)
  Rectangle 0,0 - %maxx,%maxy

  UseBrush 1,RGB(255,200,40)
  Ellipse 0,0 - 400,300

  ' -----------------------------------------------------
  EndPaint
Endproc

SubClassProc
  If %smessage = ~WM_PAINT
    dc& = ~BeginPaint(&sWnd, ps#)
    NeuZeichnen(dc&)
    ~EndPaint(&sWnd, ps#)
    Set("WinProc", 0)
  Endif
EndProc

var d1& = Create("Dialog",%hwnd,"Dialog",200,200,400,300)
var d2& = Create("Window",%hwnd,"Window",400,400,400,300)

' Dialoge hier schonmal neuzeichnen, weil uns das Subclassing
' mit XProfan WM_INITDIALOG nicht abfragen lässt
'
Neuzeichnen(~GetDC(d1&))
Neuzeichnen(~GetDC(d2&))

' Jetzt erst die Controls für die Dialoge
'
Create("Button",d1&,"Ein Button",140,140,120,40)
Create("Button",d2&,"Ein Button",140,140,120,40)

SubClass d1&, 1
SubClass d2&, 1

While 1

  WaitInput
  Case %key=2: BREAK

EndWhile

Leider lässt sich WM_INITDIALOG im Subclassing nicht abfragen, darum muß man - zumindest unter Windows 7 - das erste Neuzeichnen manuell übernehmen.

[Andreas Miethe]

Hallo Frank,

für einen einfachen Hintergrund sollte eine Reaktion auf ''WM_CTLCOLORDLG'' reichen.

'######################
'Header-Dateien
'######################
$H Windows.ph
$H Messages.ph
'######################

Windowstyle 543

$H Windows.ph
Declare Ende&,Ende1&,Win02&
CLS ~GetSysColor(~Color_BTNFACE)

'Der Brush wird von Windows benutzt um den Dialoghintergrund zu zeichnen
Var Dialogpinsel& = ~Createsolidbrush($FFFF80)

Var Button& = CREATE("BUTTON",%hwnd,"Dialog öffnen",10,10,150,25)
WindowTitle "Test..."
Whilenot Ende&
  Waitinput
  If Clicked(Button&)

    win02&=CREATE("Dialog",%hwnd,"Dialog",(%MaxX/2-300),(%MaxY/2-250),600,500)
    'einmal die Farbe geben
    Startpaint win02&
      cls $FFFF80
    Endpaint
    'Subclassing einschalten
    SubClass win02&,1
    Whilenot Ende1&
      WAITINPUT
      If %Key = 2
        Ende1& = 1
      endif
    Endwhile
    DestroyWindow(win02&)

  ElseIf %Key = 2
    Ende& = 1
  Endif
Endwhile
DeleteObject Dialogpinsel&
End

SubClassProc
  If SubClassMessage(win02&,~WM_CTLCOLORDLG)
    Set("WinProc", 0)
    '~WM_CTLCOLORDLG erwartet als Rückgabewert einen Brush für den Hintergrund
    Return Dialogpinsel&
  EndIf
EndProc

[Fraenki]

Erst gefunden. Geht das auch ohne großen Aufwand ohne Subclass.
Wenn man eine Unit verwendet ist es halt nicht so gut mit Subclass.
Momentan behelfe ich mir in ner Unit halt so, daß ich Startpaint verwende, aber nach dem Zeichnen des Hintergrunds mit CLS Farbe& sind die Objekte verschwunden.
Muss diese erst alle wieder mit ShowWindow(...,1) hervorrufen???

[Frabbing]

Bei meinem Code müsstest du die WM_PAINT-Abfrage eben in die Hauptschleife verlegen und ggf. WM_PAINT als Usermessage deklarieren, damit es sicher abgefangen wird. Ich fürchte aber, dass läuft dann zu schleppend. Aber ausprobieren.

[ts-soft]

Eine Unit hat keine Hauptschleife, die hat das Programm

[Frabbing]

Deswegen kann man aber einen Aufruf in der Hauptschleife plazieren.

[ts-soft]

Zitat von Frabbing

Deswegen kann man aber einen Aufruf in der Hauptschleife plazieren.

Ohne Eingriff des Programmieres (nicht des Unit-Erstellers) sollten auch keine
Dialoge gefärbt, geskinnt oder sonstwas werden, und dann auch nur, wenn
es sich um einen MediaPlayer oder ähnlich handelt.
Ich persönlich hasse es, wenn Controls oder Dialoge nicht das von mir in
Windows eingestellte Farbschema nutzen, sieht einfach scheisse aus .

[Frabbing]

Hasse ich auch, so ein Extrem-Skinning. Aber gegen ein dezentes Logo oben oder seitlich im Fensters spricht sicher nichts, macht Programme oft etwas freundlicher, wenn's im Rahmen bleibt.

[offtopic]Mein Monitor hat Anlaufzeiten von über ner Minute und erzeugt seltsame Doppelbilder. Da ist wohl bald ein neuer fällig... [/offtopic]

[Fraenki]

Zitat von Frabbing

Hasse ich auch, so ein Extrem-Skinning. Aber gegen ein dezentes Logo oben oder seitlich im Fensters spricht sicher nichts, macht Programme oft etwas freundlicher, wenn's im Rahmen bleibt.

[offtopic]Mein Monitor hat Anlaufzeiten von über ner Minute und erzeugt seltsame Doppelbilder. Da ist wohl bald ein neuer fällig... [/offtopic]

Genau, dazu wollte ich es benutzen und mache das ja auch schon. Nur um Infos zu zeigen, sonst lasse ich die Dialoge so wie sie sind.

[Frabbing]