Bekomme es einfach nicht hin :)

[horsthorn]

In XProfan-10 (habe 11.2) ist schon die Möglichkeit, Tab-Controls mit einem Icon zu versehen. Anscheinend bin ich dafür zu blöde ! - Wer kann mir einen Startcode geben. Mein Dank wird ihm gewiss sein !

[Jac de Lad]

Das geht aber nur per API. Ich hatte mal was, muss ich mal schauen...dauert n moment. Ich meld mich heute abend

[Bangkok]

Hallo Horst,

Hier ist ein Code, weiß nicht mehr wo ich ihn herhabe, könnte von Roland sein. Das ist bestimmt das gleiche was Jac hat. Es ist ihm gewidmet.

$H windows.ph
$H messages.ph
$H commctrl.ph
$H structs.ph

Struct TCItem = mask&, \
                 dwState&,\
                 dwStateMask&,\
                 pszText&, \
                 cchTextMax&, \
                 iImage&, \
                 lParam&

CLS

var TCItem# = New(TCItem)
var TabCtrl& = create("TabCtrl", %HWnd, "Test", 300, 10, 200, 200)

' Wir ändern den Text von Tab 0 (= 1. Reiter) per API

var NeuText$ = "Hallo Jac!"
with TCItem#
   .mask& = ~TCIF_TEXT     ' Was ist zu schreiben bzw. zu lesen
   .pszText& = Addr(NeuText$)
   .cchTextMax& = 255
endwith  
SendMessage(TabCtrl&, ~TCM_SETITEM, 0, TCItem#)

waitInput

' Und nun fügen wir eine Imgelist hinzu ...

var hToolBmp& = create("hPic", 0, "TOOLBAR")
var hIL& = Create("ImageList", 16, 16, hToolBmp&, rgb(192, 192, 192))

SendMessage(TabCtrl&, ~TCM_SETIMAGELIST, 0, hIL&)

' ... und weisen dem 1. Reiter (Tab 0) ein Bild zu)

with TCItem#
   .mask& = ~TCIF_IMAGE     ' Was ist zu schreiben bzw. zu lesen
   .iImage& = 20            ' das 20. Bild
endwith  
SendMessage(TabCtrl&, ~TCM_SETITEM, 0, TCItem#)

waitkey

dispose TCItem#
end

[Jac de Lad]

Ja, so in etwa. Du warst schneller.

[Bangkok]

Hallo Horst,

da ich weiß, dass mit API nicht viel machen willst. Hier in reinem XProfan ab 11

WiNDOWSTYLE 31+512
WINDOW 640,400

var pic& = create("hPic", 0, "TOOLBAR")
var himg&=Create("ImageList", 16, 16, pic&,rgb(255, 251, 255))
deleteobject pic&

var TabCtrl& = create("TabCtrl", %HWnd, himg&, 0, 0, 300, 200)
Inserttab(TabCtrl&,0,"Tab1",1)
Inserttab(TabCtrl&,1,"Tab2",2)
Inserttab(TabCtrl&,2,"Tab3",3)

waitinput

[horsthorn]

Danke schön an alle für die schnelle Antwort
Dieter, du scheinst mich ja sehr gut zu kennen

Hier ist der Erfolg:

[Bangkok]

Horst,

du hast es ja oft genug erwähnt, dass du XProfan Purist bist, das prägt sich ein

[AHT]

Zitat von horsthorn

Danke schön an alle für die schnelle Antwort
Dieter, du scheinst mich ja sehr gut zu kennen

Hier ist der Erfolg:

Sehr schön! Wann kann man einen Blick auf das Ergebnis werden.

[horsthorn]

@Andreas

Sehr schön! Wann kann man einen Blick auf das Ergebnis werden.

Gib mir noch 48 Stunden Zeit !

PS: Wie war der Urlaub ?