Bitte um Test unter Vista 64Bit

[AHT]

IN einem M$ Forum habe ich vor kurzem ein etwas merkwürdiges Posting gelesen - habe da jetzt eine Befürchtung und möchte gerne Wissen, ob diese Befürchtung zutrifft oder nicht.






Könnte jemand mit Vista 64Bit bitte mal den unten stehenden Quelltext auf diese Art testen:

• Programm starten
• Checkbox nicht abhaken
• Testen Button klicken
• Screenshot posten

danach

• Checkbox abhaken
• Testen Button klicken
• Screenshot posten

Bin gespannt - danach kommt evtl. noch ein zweiter Test...

'#####################################################################################
'#########                   Code von AHT                                    #########
'#########      Gepostet für http://www.paules-pc-forum.de                   #########
'#####################################################################################
 
Def GetFileVersionInfoSize(2) !"VERSION", "GetFileVersionInfoSizeA"
DEf VerQueryValue(4) !"VERSION", "VerQueryValueA"
Def GetFileVersionInfo(4) !"VERSION", "GetFileVersionInfoA"
DEF GetProcAddress(2) !"KERNEL32.dll", "GetProcAddress"
DEF GetModuleHandle(1) !"KERNEL32", "GetModuleHandleA"
 
Declare FEHLER&, FILE$, Zero&, Info_Size&, FileInfoSize&, MODULEINFO#, FILE_VER_INFO&, FILE_VER_INFO#
Declare VERSION$, Ver_Value$
Declare Edit&, Button&, Checkbox&, Wow64DisableWow64FsRedirection&, OldValue&
Declare Wow64EnableWow64FsRedirection&, version&
Declare Module$, MHANDLE&, Funktion$
Declare 64Bit&, GetFileVersionInfoSizeA&
Declare GetFileVersionInfoA&, FILE_FEHLER&
 
version&=UseDLL("version.dll")

Funktion$ = "GetFileVersionInfoSizeA"
GetFileVersionInfoSizeA& = GetProcAddress(version&, ADDR(FUNKTION$))
Funktion$ = "GetFileVersionInfoA"
GetFileVersionInfoA& = GetProcAddress(version&, ADDR(FUNKTION$))
Module$ = "Kernel32.DLL"
MHANDLE& = GetModuleHandle(ADDR(Module$))
Funktion$ = "Wow64DisableWow64FsRedirection"
Wow64DisableWow64FsRedirection& = GetProcAddress(MHANDLE&, ADDR(FUNKTION$))
Funktion$ = "Wow64EnableWow64FsRedirection"
Wow64EnableWow64FsRedirection& = GetProcAddress(MHANDLE&, ADDR(FUNKTION$))

Funktion$ = "IsWow64Process"
MHANDLE& = GetModuleHandle(ADDR(Module$))
IF GetProcAddress(MHANDLE&, ADDR(FUNKTION$))<>0
 External("Kernel32.dll", "IsWow64Process", External("Kernel32", "GetCurrentProcess"), Addr(64Bit&))
endif
 
Windowstyle 31 + 512
WindowTitle "Resourcen Test"
Window 0, 0 - 640, 440
Usermessages $10

Edit& = Create("Edit", %HWND, "C:\Windows\System32\Drivers\ACPI.SYS", 20, 20, 500, 30)
Button& = Create("Button", %HWND, "Testen", 20, 60, 500, 30)
Checkbox& = Create("CheckBox", %HWND, "Umleitung deaktivieren", 20, 100, 500, 30)

While %Umessage <> $10
 Waitinput
 IF Clicked(Button&)
  EnableWindow Checkbox&, 0
  EnableWindow Button&, 0
  CLS
  Locate 12, 0
  File$ = Gettext$(Edit&)
  IF File$ <> ""
   CLS
   Locate 12, 0
   Print "Versionsnummer der Datei: "
   Print GetFileVersion(File$)
  endif
  EnableWindow Checkbox&, 1
  EnableWindow Button&, 1
 endif
EndWhile
Freedll version&
End
 
Proc GetFileVersion
 Parameters File2$
 Clear Version$
 'Umleitung deaktivieren
 IF (GetCheck(Checkbox&)) and 64Bit& = 1 : Set("FastMode", 1) : Call(Wow64DisableWow64FsRedirection&, addr(OldValue&)) : endif
 FileInfoSize& = Call(GetFileVersionInfoSizeA&, ADDR(File2$), ADDR(Zero&))
 IF FileInfoSize& > 0
  DIM MODULEINFO#, FileInfoSize&
  FILE_FEHLER& = Call(GetFileVersionInfoA&, ADDR(File2$), 0, FileInfoSize&, MODULEINFO#)
  'Umleitung aktivieren
  IF (GetCheck(Checkbox&)) and 64Bit& = 1 : Call(Wow64EnableWow64FsRedirection&, addr(OldValue&)) : Set("FastMode", 0) : endif
  Ver_Value$ = "\\"
  FEHLER& = VerQueryValue(MODULEINFO#, ADDR(Ver_Value$), ADDR(FILE_VER_INFO&), ADDR(Zero&))
  If FEHLER& = 1
   If Zero& = 0
    Zero& = 4
   endif
   DIM FILE_VER_INFO#, Zero&
   Clear FILE_VER_INFO#
   FILE_VER_INFO# = FILE_VER_INFO&
   VERSION$ = STR$(Word(FILE_VER_INFO#, 10)) + ", "
   VERSION$ = Version$ + STR$(Word(FILE_VER_INFO#, 8)) + ", "
   VERSION$ = Version$ + STR$(Word(FILE_VER_INFO#, 14)) + ", "
   VERSION$ = Version$ + STR$(Word(FILE_VER_INFO#, 12))
   Dispose FILE_VER_INFO#
  endif
  Dispose MODULEINFO#
 endif
 'Umleitung aktivieren
 'IF (GetCheck(Checkbox&)) and 64Bit& = 1 : Call(Wow64EnableWow64FsRedirection&, addr(OldValue&)) : Set("FastMode", 0) : endif
 Return Version$
endproc

Hier die Testdatei als EXE zum Downloaden.

[Sascha Oliver Haak]

@AHT

Schau mal Vista64

Gruß
Sascha

[AHT]

- Aua, ich schon wieder - .
Ich habe mir beim Copy / Paste einen kleinen Fehler reingehauen, den meine Profanversion nicht erkennt. Habe den Quelltext korrigiert und bitte jetzt nochmals um Test unter Vista 64Bit (und hoffe, dass der Code jetzt das tut, was ich will ).

[Sascha Oliver Haak]

@AHT

Schau jetzt noch einmal

Gruß
Sascha

[AHT]

DANKE! Befürchtung 1 hat sich nicht bestätigt.
Muss noch etwas Code schreiben, dann melde ich mich noch einmal für einen anderen Test.

[AHT]

So, jetzt Test zwei, wieder Vista 64Bit.





Bitte mit dem Code unten genau so verfahren, wie ich das jetzt hier angebe:

• Code starten
• Checkbox abhaken
• Button Testen drücken
• Screenshot posten

danach

• Checkbox haken entfernen
• Button Testen drücken
• Screenshot posten

als nächstes

• System32 im Edit durch SysNative ersetzen
• Button Testen drücken
• Screenshot posten

zuletzt

• Code neu starten
• System32 im Edit durch SysNative ersetzen
• Button Testen drücken
• Screenshot posten

...bin gespannt, was Vista sagt.
Hier der Code:

'#####################################################################################
'#########                          Code von AHT                             #########
'#########      Gepostet für http://www.paules-pc-forum.de                   #########
'#####################################################################################

 
DEF GetProcAddress(2) !"KERNEL32.dll", "GetProcAddress"
DEF GetModuleHandle(1) !"KERNEL32", "GetModuleHandleA"
 
Declare File$
Declare WINTRUST_FILE_INFO#, WINTRUST_DATA#, WintrustFile#, WINTRUST_ACTION_GENERIC_VERIFY_V2#, FMess#
Declare WinVerifyTrust&, Wintrust&
Declare Edit&, Button&, Checkbox&, Wow64DisableWow64FsRedirection&, OldValue&
Declare Wow64EnableWow64FsRedirection&
Declare Module$, MHANDLE&, Funktion$
Declare 64Bit&
 
Wintrust& = UseDLL("Wintrust.dll")
 
Funktion$ = "WinVerifyTrust"
WinVerifyTrust& = GetProcAddress(Wintrust&, ADDR(FUNKTION$))
Module$ = "Kernel32.DLL"
MHANDLE& = GetModuleHandle(ADDR(Module$))
Funktion$ = "Wow64DisableWow64FsRedirection"
Wow64DisableWow64FsRedirection& = GetProcAddress(MHANDLE&, ADDR(FUNKTION$))
Funktion$ = "Wow64EnableWow64FsRedirection"
Wow64EnableWow64FsRedirection& = GetProcAddress(MHANDLE&, ADDR(FUNKTION$))
 
Funktion$ = "IsWow64Process"
MHANDLE& = GetModuleHandle(ADDR(Module$))
IF GetProcAddress(MHANDLE&, ADDR(FUNKTION$)) <> 0
 External("Kernel32.dll", "IsWow64Process", External("Kernel32", "GetCurrentProcess"), Addr(64Bit&))
endif
 
Windowstyle 31 + 512
WindowTitle "Resourcen Test"
Window 0, 0 - 640, 440
Usermessages $10
 
Edit& = Create("Edit", %HWND, "C:\Windows\System32\Drivers\ACPI.SYS", 20, 20, 500, 30)
Button& = Create("Button", %HWND, "Testen", 20, 60, 500, 30)
Checkbox& = Create("CheckBox", %HWND, "Umleitung deaktivieren", 20, 100, 500, 30)
 
While %Umessage <> $10
 Waitinput
 IF Clicked(Button&)
  Locate 12,0
  File$ = Gettext$(Edit&)
  Print VerifyFile(File$, 1)
 endif
EndWhile
Freedll Wintrust&
end
 
Proc VerifyFile
 Parameters Verify_Filename$, FMess%
 Declare WINTRUST_ACTION_GENERIC_VERIFY_V2$, VerRet6&, WINTRUST_ACTION_GENERIC_VERIFY$
 Declare VerRet6$, CRYPT_PROVIDER_DATA&, CRYPT_PROVIDER_SGNR&, CRYPT_PROVIDER_CERT&
 DIM WINTRUST_FILE_INFO#, 16
 DIM WINTRUST_DATA#, 48
 DIM WintrustFile#, 2000
 DIM WINTRUST_ACTION_GENERIC_VERIFY_V2#, 16
 Clear WINTRUST_FILE_INFO#, WintrustFile#
 External("kernel32", "MultiByteToWideChar", 0, 0, addr(Verify_Filename$), -1, WintrustFile#, 600)
 Clear WINTRUST_DATA#
 LONG WINTRUST_FILE_INFO#, 0 = SizeOf(WINTRUST_FILE_INFO#)
 LONG WINTRUST_FILE_INFO#, 4 = WintrustFile#
 LONG WINTRUST_DATA#, 0 = SizeOf(WINTRUST_DATA#)
 LONG WINTRUST_DATA#, 12 = 2
 LONG WINTRUST_DATA#, 20 = 1 'File
 LONG WINTRUST_DATA#, 24 = WINTRUST_FILE_INFO#
 LONG WINTRUST_DATA#, 40 = $0
 LONG WINTRUST_DATA#, 44 = 0
 Long WINTRUST_ACTION_GENERIC_VERIFY_V2#, 0 = $00AAC56B
 Word WINTRUST_ACTION_GENERIC_VERIFY_V2#, 4 = $CD44
 Word WINTRUST_ACTION_GENERIC_VERIFY_V2#, 6 = $11D0
 Word WINTRUST_ACTION_GENERIC_VERIFY_V2#, 8 = $C28C
 Byte WINTRUST_ACTION_GENERIC_VERIFY_V2#, 10 = $00
 Byte WINTRUST_ACTION_GENERIC_VERIFY_V2#, 11 = $C0
 Byte WINTRUST_ACTION_GENERIC_VERIFY_V2#, 12 = $4F
 Byte WINTRUST_ACTION_GENERIC_VERIFY_V2#, 13 = $C2
 Byte WINTRUST_ACTION_GENERIC_VERIFY_V2#, 14 = $95
 Byte WINTRUST_ACTION_GENERIC_VERIFY_V2#, 15 = $EE
 LONG WINTRUST_DATA#,40 = $100
 'Umleitung deaktivieren
 IF (GetCheck(Checkbox&)) and 64Bit&  =  1 : Set("FastMode",  1) : Call(Wow64DisableWow64FsRedirection&,  addr(OldValue&)) : endif
 VerRet6& = Call(WinVerifyTrust&, 0, WINTRUST_ACTION_GENERIC_VERIFY_V2#, WINTRUST_DATA#)
'Umleitung aktivieren
 IF (GetCheck(Checkbox&)) and 64Bit&  =  1 : Call(Wow64EnableWow64FsRedirection&,  addr(OldValue&)) : Set("FastMode",  0) : endif
 External("kernel32.dll", "GetLastError")
 Dispose WintrustFile#
 Dispose WINTRUST_DATA#
 Dispose WINTRUST_FILE_INFO#
 Dispose WINTRUST_ACTION_GENERIC_VERIFY_V2#
 CASE FMess% = 0 : return VerRet6&
 DIM FMess#, 64000
 External("kernel32", "FormatMessageA", $1000, 0, VerRet6&, 0, FMess#, 32000, 0)
 VerRet6$ = String$(FMess#, 0)
 Dispose FMess#
 Return VerRet6$
endproc

[Sascha Oliver Haak]

@AHT

Guckst Du jetzt

Gruß
Sascha

[AHT]

Hammerhart - besten Dank. Was hat sich M$ da denn geleistet?
Die Sache ist sogar noch ganz anders, als im M$ Forum stand.

[p. specht]

Frage@AHT: Betreibt M$ deiner Meinung nach ABSICHTLICH Desinformation?

[AHT]

Im Fall von WinVeriFyTrust scheint ein schwerer Fehler vorzuliegen - das ist wohl keine Absicht.
Bei manchen Sachen ist das ganz offensichtlich Absicht - siehe native API.
In der Regel liegen aber irgendwelche Fehler vor, die nicht erkannt werden, weil kaum jemand die besagten APIs nutzt.

[AHT]

Die MSDN Dokumentation ist an vielen Stellen nicht komplett und fehlerhaft. Blind auf das zu vertrauen, was dort steht, ist auf jeden Fall falsch.

[AHT]

Wenn mir irgendetwas spanisch vorkommt oder ich Grund zur Annahme habe, das etwas unter Umständen anders ist, als bei MSDN beschrieben, gehe ich in der Regel der Sache nach. Deswegen auch dieser Thread hier.

[Chris_S]

Mich verwundert ehrlich gesagt ein wenig das sich Vista die Umleitung deaktivieren lässt ohne nach Adminrechten zu schreien. Manchmal glaube ich das wurde ausgewürfelt.

Edit: Argh, jetzt bin ich im Sammelthread gelandet mit meinem Post -.-
Bitte verschieben nach Bitte um Test unter Vista 64Bit

Edit Frabbing: Erledigt

[AHT]

Warum sollte man dafür Adminrechte benötigen? Es geht ja nur um das laden der richtigen DLLs...

[Chris_S]

Wie ich dich verstanden hatte wird das global deaktiviert, was ja schon einen recht ordentlichen Eingriff darstellt.