Doppelten Programmstart verhindern

[JörgG]

Hi Leute,
jetzt möchte ich verhindern, das mein Prog. 2x gestartet wird (Katastrophe). Deshalb suchte ich hier & in der Hilfe & im I-net ganz gezielt nach diesem Problem. In einigen Foren war von der Erstellung eines Mutex die Rede; kann er erstellt werden ist alles OK, wenn nicht, ist er bereits vorhanden (sprich, das Prog ist bereits gestartet) - Also genau das, was ich brauche.
Nun habe ich (bis jetzt) vergeblich nach einer ähnlichen Funktionalität im Profan-Funktionsumfang gesucht, aber vllt. heißt die auch ganz anders, als ich erwarte. Könnt ihr mich da ein wenig auf die Sprünge helfen, in welche Richtung ich da stöbern bzw. ansetzen kann?
Danke & viele Grüße
Jörg

[AHT]

Def Createmutex(3) !"KERNEL32","CreateMutexA"
Def Getlasterror(0) !"KERNEL32.dll","GetLastError"
 
IF Check_doppelstart("Testprogramm für Mutex")=0
 end
endif
 
Windowstyle 31
Windowtitle "Nur einmal starten!"
window 0,0-640,440
 
While 1
 waitinput
Endwhile
 
Proc Check_doppelstart ' return ist 0 wenn doppelstart vorliegt
  Parameters Name$    ' Mutexname
  Declare Mutex&,Error&
  Name$ = Translate$(Name$ ,"\\","/")
  Mutex& = Createmutex(0,1,Addr(Name$))
  Error& = Getlasterror()
  If Error& = 183
   Return 0
  Endif
  Return 1
Endproc

[Bangkok]

Ich verlasse mich bei neueren Windows Versionen nicht mehr so toll auf den Mutex, da er mich schon oft im Stich gelassen hat. Ein vielleicht besserer Weg. Ich benenne mein Programm beim Starten mit irgend einem Namen z.B. "X_Y_Z=0" Suche dann mit Findwindow("mein Programmname") nach dem richtigen Namen des Programmes, wenn kein Handle zurück gegeben wird, benenne ich es dann um in den richtigen Namen und starte es. Im Falle eines Handles beende ich es. Hat nur den Nachteil wenn ein anderes Programm mit diesem Namen läuft, geht es schief. Läßt sich aber umgehen mit irgendeinem speziellen Zeichen im Namen.

[AHT]

Wo gab es bei dir Probleme mit einem Mutex?

[AHT]

Aufgrund des ILs und der Zugriffsrechte kann es da Probleme geben, wenn man keinen Security Descriptor für das Mutex festlegt. Hier neuer Vorschlag, müsste ausgetestet werden, ob er in allen Lebenslagen geht:

'#####################################################################################
'#########                          Code von AHT                             #########
'#########      Gepostet für http://www.paules-pc-forum.de                   #########
'#####################################################################################
 
Def Createmutex(3) !"KERNEL32","CreateMutexA"
Def Getlasterror(0) !"KERNEL32.dll","GetLastError"
Def Setlasterror(1) !"KERNEL32.dll","SetLastError"
 
IF Check_doppelstart("Testprogramm für Mutex")=0
 end
endif
 
Windowstyle 31
Windowtitle "Nur einmal starten!"
window 0,0-640,440
 
While 1
 waitinput
Endwhile
 
Proc Check_doppelstart ' return ist 0 wenn doppelstart vorliegt
  Parameters Name$    ' Mutexname
  Declare Mutex&,Error&
  Name$ = Translate$(Name$ ,"\\","/")
  Setlasterror(0)
  Mutex& = Createmutex(0,1,Addr(Name$))
  Error& = Getlasterror()
  'Print Error&
  If Error& = 183
   Return 0
  Elseif Error& = 5
   Return 0
  Endif
  Return 1
Endproc

[JörgG]

Joooooooo super! Gleich 2 Lösungen!
@AHT ja ja - die API....wie hast du denn das so schnell aus den Ärmel gezaubert - genial also liefert die API genau den Fehler 183, wenn der Mutex nicht erstellt werden konnte? Vermute mal, das im Erfogsfall die ProzessNr. zurückgeliefert wird...

@Bangkok pfiffige Alternative, spontan tut sich bei mir die Frage auf, wie man zur Laufzeit eines Progs seinen Namen ändern kann, oder ich müßte so eine Art seperates Startprogramm basteln, welches schaut ob das Hauptprog als Fenster vorhanden ist?
Alles Klar - ich erstelle ja ein Fenster mit einem beliebigen Namen.... Jetzt hab ich's gescheckt...

[AHT]

Verwende den letzten Code, der erste wird nicht funktionieren, wenn das Programm zuerst mit Adminrechten und danach geringer priveligiert gestartet wird.
Wird das Programm mit Adminrechten gestartet, wird dem Mutex eine Standard Sicherheitsbeschreibung verliehen (wird aus dem Default DACL des Prozesses genommen, der das Mutex erzeugt), und ein niedriger priveligierter Prozess hat dann keinen Zugriff auf das Mutex.

Fehler 183:

Eine Datei kann nicht erstellt werden, wenn sie bereits vorhanden ist.

Feher 5:

Zugriff verweigert

Ansonsten 0:

Der Vorgang wurde erfolgreich beendet.

[JörgG]

Ok - ich bau das ein & guck, was passiert
Vielen Dank für die Tips

[Jac de Lad]

Ich benutz auch Mutex und hatte nie Probleme.

[Bangkok]

Ich hatte Probleme, dass bei ca 5% der Starts der Mutex nicht erstellt wurde.

@AHT: Sollte man nicht besser das Handle des Mutex mit der Api closehandle wieder schließen.

@Jörg: Ein Startprogramm braucht man nicht es reicht schon am Anfang

If Findwindow("Mein Programmname") = 0
settext %hwnd,"Mein Programmname"
else
end
endif

[AHT]

@Jack:
Compilere mal den ersten Quelltext und starte ihn mit Adminrechten.
Starte danach den ersten Quelltext nochmals so, das er in einem Integritätslevel "niedrige Verbindlichkeitsstufe" läuft (geht hiermit ganz gut).
Was erkennts du? Warum das so ist, lässt sich recht einfach erklären.

[AHT]

Zitat von Bangkok

Ich hatte Probleme, dass bei ca 5% der Starts der Mutex nicht erstellt wurde.

Ich überprüfe das mal - das Problem kenne ich nicht.

Zitat von Bangkok

@AHT: Sollte man nicht besser das Handle des Mutex mit der Api closehandle wieder schließen.

Nein, Kernelhandles sind prozessspezifisch. wird automatisch beim Beenden gekillt.

[Jac de Lad]

@Bangkok:
Zur Sicherheit release ich den Mutex immer vor Programmende mit

Def ReleaseMutex(1) !"kernel32","ReleaseMutex"
ReleaseMutex(handle&)

@AHT: Bitte Jac, nicht Jack. Solche speziellen Sachen habe ich noch nie ausprobiert. Ich starte meine Programme imme ganz normal und das hat noch nie Probleme gemacht.

[Hallo1001]

Hallo Jörg!

Ich habe das Problem bei mir über einen gemeinsamen Speicherbereich gelöst. Beim Programmstart wir der Handel in den Speicher geschrieben. Startet das Programm dann noch einmal, wird erst der Speicher abgefragt und ist der Handel noch vorhanden, dann wird das neue Programm an der Stelle beendet. Anbei mal ein kleines Test-Progi dazu, vielleicht kannst Du es ja gebrauchen...

LG Jens

$H Windows.ph                      ' Headerdatei laden
 
Proc Memory
   Parameters Tmp_SizeOfMem&                ' Übergabe - Größe des Speicherplatzes
   Var Tmp_hMap& = ~CreateFileMapping(-1,0,~PAGE_READWRITE,0,Tmp_SizeOfMem&,"Mein_Test")  ' Speicherbereich anlegen
   Var Tmp_hMapView& = ~MapViewOfFile(Tmp_hMap&,$000F001F,0,0,0)  ' Zeiger vom Speicherbereich ermitteln
   Return Tmp_hMapView&                     ' Handel zurück geben
EndProc
 
' Memory Speicher erstellen
Var Zeiger_Mem& = Memory(256)               ' Speicherplatz bereitstellen und Handel ermitteln
 
' Handel des letzten Programmstarts einlesen
Var Progi& = @Long(Zeiger_Mem&,0)           ' Handel der vorigen Sitzung aus Memory einlesen
' Überprüfe ob dass vorige Progi noch läuft
IfNot ~IsWindow(Progi&) = 0                 ' wenn dass vorige Programm noch läuft, dann...
   ' Meldung im Memory hinterlegen
   Long Zeiger_Mem&,4 = 1                   ' Meldung hinterlegen
   @SendKey(Progi&,13)                      ' Sende Enter an vorige AVR-Brenner Sitzung
   ' Memory Speicher freigeben
   ~UnmapViewOfFile(Zeiger_Mem&)            ' Speicherbereich abmelden
   ~CloseHandle(Zeiger_Mem&)                ' Bereitstellung beenden
   End                                      ' Neue Sitzung beenden
EndIf
 
'------------------------------------------------
CLS
' Handel des aktuellen Programms sichern
Long Zeiger_Mem&,0 = %hWnd                  ' Handel Hauptfenster im Memory hinterlegen
Print "Fenster mit Handel: "+str$(%hWnd)
Var Ende% = 0                               ' Endlosschleife einstellen
WhileNot Ende%                              ' Beginn Endlosschleife
   WaitInput                                ' warten auf Eingabe (Mausklick)
   If (%Key = 2) or (%Key = 27)             ' wenn X-Button oder ESC ausgewählt wurde, dann...
      Ende% = 1                             ' Programm Ende
   EndIf
 
EndWhile                                    ' Ende Endlosschleife
 
'------------------------------------------------
' Memory Speicher freigeben
~UnmapViewOfFile(Zeiger_Mem&)               ' Speicherbereich abmelden
~CloseHandle(Zeiger_Mem&)                   ' Bereitstellung beenden
end

[Bangkok]

@AHT: deinen zweiten Vorschlag kann ich unbegrenzt oft starten, geht also garnicht
Win 7