XProfan-Version auslesen

[horsthorn]

Natürlich ist mir $Profver bekannt,
für einen bestimmten Zweck müsste ich aber aus dem fertig erstellten Programm die XProfan-Version auslesen.
Also das erstellte Programm nennt sich als Beispiel jetzt nach Compilieren und Linken
TEST.EXE
Wie kann ich jetzt aus dieser EXE-Datei die XProfan-Version raus lesen ?

[RGH]

Hallo Horst,
nur rasch einige Ideen auf die Schnelle (ich bin noch in der Firma):
- Bei neueren Versionen kannst Du die Versionressource auslesen. Diese zeigt, so sie nicht verändert wurde, die verwandte XProfan-Version.
- Eine weitere Möglichkeit ist, den Anfang des Compilates zu finden und auszuwerten. Da steht dann etwa " RGH-PROFANx DATEI", wobei das Zeichen an Position x die Version eingrenzt.

Gruß
Roland

[horsthorn]

@Roland
Hab das jetzt so gelöst. Kann man lassen oder ?

VAR datei$=GETDIR$("@")+"a-1-b.exe" 'Hier natürlich anpassen
VAR vers_info$ = LEFT$(datei$,15)

CLS
PRINT vers_info$
VAR version$=RIGHT$(vers_info$,2)
IF version$ < "12"
Messagebox("Falsche PROFAN.EXE-Version",vers_info$,64)
END
ENDIF
WAITINPUT
END

[Jac de Lad]

@Horst: ???
Nein, du schneidest doch nur Teile des Dateinamens aus.

Du musst die Datei öffnen (OpenRW) und dann die ersten 15 Byte auslesen (siehe Hilfe).

[Bangkok]

Nein ich denke nicht die ersten 15 Bytes, er muss den wohl den Beginn der Runtime suchen, ich denke die Runtime beginnt mit dem Begriff oder besser gleichen den ganzen Begriff "RGH-PROFAN" suchen und dann auslesen was dahinter steht. Ich war auch über den Code erstaunt, da er ja aber an Roland gerichtet war habe ich mal nichts dazu geschrieben. Nach Rolands Posting muss er den Beginn des Compilates finden, dann steht die Runtime am Beginn, denn der Begriff ist ziemlich weit hinten zu finden.

[AHT]

Der compilierte Code, der an die Runtime angehängt wird, beginnt mit dem Begriff.

[AHT]

PS: Ist in der Regel der letzte String dieser Art, der in der Datei auftaucht.

[horsthorn]

Da ich mich ja hier auf "Glatteis" begeben habe, hab ich halt mal einen Code hierhin gestellt in der Hoffnung, daß die "Grauen Eminenzen" sich melden
Hat ja auch funktioniert !

Assign #1, datei$
OpenRW #1
version$= GETCHAR$(#1,15)
print version$
Close #1

Wenn ich jetzt die ersten 15 Zeichen aus der EXE-Datei lese, steht da nix von XPROFAN usw...
Wie suche ich denn in einer binären Datei ?

[AHT]

So kommst du auf keinen grünen Zweig. Warum nicht $Profver?

[AHT]

Ach so - habe jetzt verstanden. Wenn ich Zeit habe, bastele ich dir was.
Du brauchst von Roland noch die Liste mit den Buchstaben für die jeweilige Profanversion.
Buchstabe B ist bei mir die Version 9.

@Roland - hast du mal die Liste?

[horsthorn]

@Andreas
Der Sinn der Übung ist folgender.
Habe ein kleines Tool gebastet, welches aber nur ab der Version XProfan-12 läuft.
Also muss ich vorher erkennen können, mit welcher XProfan-Version die jeweilige EXE-Datei erstellt wurde. D. h., wenn ich mit meinem Tool eine mit XProfan erstellte EXE-Datei aufrufe, muss sofort erkannt werden, ob es < 12 oder => 12 ist.
Das Tool werde ich, sobald Roland die 12er-Version frei gegeben hat, auf meiner HP im XProfan-Bereich zum Download stellen. Es ist eine Hilfe für das Auswechseln der neuen Icon in XProfan-12. Frank Abbing hat getestet und "für gut befunden !" Jetzt fehlt nur noch dieses Aussortieren vor dem Programmstart.

[AHT]

Wie gesagt, man müsste wissen, wie Roland die Versionen Buchstabenmäßig durchnummeriert. Alles andere ist ein Kinderspiel.

[Bangkok]

Beim RC von XProfan 12 ist es F, wenn es bei der endgültigen Version so bleibt, kann man das verwenden.

[Bangkok]

@Horst du änderst doch die Resourcen mit dem Tool von Frank. Ich bin davon überzeugt, dass Frank die Resource-API benutzt, damit geht das austauschen doch mit jeder Version, ja sogar mit jeder Exe-Datei, denn die API greift auf die Resourcen zu, egal an welcher Position die stehen.
Oder hast du nun was an dem Tool geändert, wozu brauchst du die Profanversion, du wirst doch hoffentlich nicht mit Blockwrite oder sowas die Resourcen schreiben.

[RGH]

Hallo,

hier ein Beispielprogramm, dass die Version einer mit XProfan erzeugten EXE ermittelt (geht nur bei 32-Bit, da bei 16 Bit die Adresse des Compilates an anderer Stelle stand):

Declare Datei$, hDatei&, Version$, Adresse&
CLS
Datei$ = LoadFile$("Profn-Programm öffnen:", "*.exe")
If Datei$ > ""        // Es wurde eine Datei ausgewählt
  hDatei& = Assign(Datei$)
  OpenRW hDatei&      // Datei binär öffnen
  Seek hDatei&, $80   // An dieser Position steht die Adresse des Compilates
  Adresse& = GetLong(hDatei&)
  Seek hDatei&, Adresse&  // hier beginnt das Compilat
  Version$ = GetChar$(hDatei&, 18)
  // Die ersten 11 Zeichen sind immer " RGH-PROFAN" 
  If Mid$(Version$, 1, 11) <> " RGH-PROFAN"
    MessageBox("Kein mit PROFAN² oder XProfan erzeugtes Programm!", "Hinweis:", 16)
    Close hDatei&
    End
  EndIf
  // Das 12. Zeichen ist die Version des Compilates und lässt Rückschlüsse auf die
  // XProfan-Version zu
  Version$ = Substr$(Version$, 12)
  Select Version$
    CaseOf "3" : Print "Profan² 5 (32 Bit)"
    CaseOf "4" : Print "Profan² 5 (32 Bit) mit $P* verschlüsselt"
    CaseOf "5" : Print "Profan² 6 (32 Bit)"
    CaseOf "6" : Print "Profan² 6 (32 Bit) mit $P* verschlüsselt"
    CaseOf "7" : Print "Profan² 7"
    CaseOf "8" : Print "Profan² 7 mit $P* verschlüsselt"
    CaseOf "9" : Print "XProfan 8"
    CaseOf "A" : Print "XProfan 8 mit $P* verschlüsselt"
    CaseOf "B" : Print "XProfan 9"
    CaseOf "C" : Print "XProfan 9 mit $P* verschlüsselt"
    CaseOf "D" : Print "XProfan 10"
    CaseOf "E" : Print "XProfan 10 mit $P* verschlüsselt"
    CaseOf "F" : Print "XProfan 11 oder X2"
    CaseOf "G" : Print "XProfan 11 oder X2 mit $P* verschlüsselt"
    Otherwise  : Print "Unbekannte Version " + Version$
  EndSelect  
  Close hDatei&
  WaitInput
EndIf
End

Gruß
Roland