SetFont

[Fraenki]

Mit SetDialogFont kann man ja einen neuen Zeichensatz für die Dialogelemente setzen.
Meine Fragen:
1.) Gibt es auch eine Möglichket den aktuell eingestellten Font zu ermitteln?
2.) Wie kann man den Systemfont ermitteln?

Gruß Fränki

[ts-soft]

Also den Systemfont kann man so ermitteln:

$H windows.ph

Proc GetSystemFont
  Declare phkResult&, lpcbData&, lplf#, hLogFont&
  
  IfNot ~RegOpenKeyEx(~HKEY_CURRENT_USER, "Control Panel\Desktop\WindowMetrics", 0, ~KEY_READ, Addr(phkResult&))
    IfNot ~RegQueryValueEx(phkResult&, "MessageFont", 0, 0, 0, Addr(lpcbData&))
      Dim lplf#, lpcbData&
      IfNot ~RegQueryValueEx(phkResult&, "MessageFont", 0, 0, lplf#, Addr(lpcbData&))
        hLogFont& = External("Gdi32.dll", "CreateFontIndirectW", lplf#)
      EndIf
      Dispose lplf#
    EndIf
    ~RegCloseKey(phkResult&)
  EndIf
  Return hLogFont&
EndProc

Proc GetSystemFontName
  Declare font&, logfont#, result$
  Dim logfont#, 60
  font& = GetSystemFont()
  ~GetObject(font&, 60, logfont#)
  result$ = String$(logfont#, 28)
  Dispose logfont#
  DeleteObject font&
  Return result$
EndProc

Proc GetSystemFontSize
  Declare font&, logfont#, result&
  Dim logfont#, 60
  font& = GetSystemFont()
  ~GetObject(font&, 60, logfont#)
  result& = LONG(logfont#, 0)
  If result& < 0
    result& = result& * -1
  EndIf
  result& = result& - 3
  Dispose logfont#
  DeleteObject font&
  Return result&
EndProc

Print GetSystemFontName()
Print GetSystemFontSize()
WaitKey

[Frabbing]

Eine weitere Methode, die ich bevorzuge ist:

$H windows.ph

Declare font&, mem#
Dim mem#, 280

font& = ~GetStockObject(~SYSTEM_FONT)
If font&
  ~GetObject(font&, 280, mem#)
  Print "System"
  Print "Name: " + String$(mem#, 28)
  Print "Größe: " + Str$(Int(Abs(Long(mem#, 0))))
  Print "Handle: $" + Hex$(font&)
  Print ""
EndIf

font& = ~GetStockObject(~DEFAULT_GUI_FONT)
If font&
  ~GetObject(font&, 280, mem#)
  Print "Gui-Font"
  Print "Name: " + String$(mem#, 28)
  Print "Größe: " + Str$(Int(Abs(Long(mem#, 0))))
  Print "Handle: $" + Hex$(font&)
  Print ""
EndIf

font& = ~GetStockObject(~ANSI_VAR_FONT)
If font&
  ~GetObject(font&, 280, mem#)
  Print "Ansi-Font"
  Print "Name: " + String$(mem#, 28)
  Print "Größe: " + Str$(Int(Abs(Long(mem#, 0))))
  Print "Handle: $" + Hex$(font&)
  Print ""
EndIf

font& = ~GetStockObject(~ANSI_FIXED_FONT)
If font&
  ~GetObject(font&, 280, mem#)
  Print "Fixed Ansi-Font"
  Print "Name: " + String$(mem#, 28)
  Print "Größe: " + Str$(Int(Abs(Long(mem#, 0))))
  Print "Handle: $" + Hex$(font&)
  Print ""
EndIf

WaitInput

Schnell hingeschrieben, darum besser die LOGFONT-Struktur benutzen als einfach einen Bereich.

@Thomas: Dein ermittelter Font ist bei mir der für die Fenster-Titelleisten.
In Dialogen ist der Ansi-Font aktiv.

[ts-soft]

Damit ist der "SystemFont", den der aktuelle Style nutzt, aber nicht gefunden
Bei mir kommt korrekter Weise: Segoe UI in der grösse 9
Bei Dir kommt: System in der grösse 16! Da würde mir schlecht werden

Aber vielleicht meint er doch den, möglich ist alles.

[Frabbing]

Von der Logik und vom Namen her sollte ~SYSTEM_FONT aber der System-Font sein. Ist halt manches merkwürdig im Windows-Märchenland.

[ts-soft]

Es kommt bei mir jedenfalls ein Font Namens "System", insofern hast Du wohl recht

[Volkmar]

Nunja, Windows ist eben auch schon in die Jahre gekommen. Diese häßliche fette Schrift kommt wohl deshalb als System_Font, weil sie SYSTEM heißt und die voreingestellte Standardschrift in 16-Bit war, denke ich mir. MS hat das dann einfach so beibehalten und nur ein paar neue, schlankere Schriften hinzugefügt und wählt daraus die Standarschrift.

Gruß Volkmar

[Fraenki]

Mache gerade eine Arbeitspause und hab die vielen Antworten gesehen.
Da ist bestimmt etwas für mich dabei, das teste ich heut Abend mal.
Systemfont ??? Ja, habe den Font gemeint den man unter den tiefen von den Systemeigenschaften einstellen kann. Glaub das ist irgendwo unter der Bildschirmanzeige zu finden.
Wollte halt nur diesen Font als Standart für meine Programme nehmen.

Vielen Dank an alle, Fränki

[Volkmar]

Da bin ich am Besten mit GUI-Font gefahren, habe aber nie nachgeprüft, ob das bei jedem denkbaren Systemschema auch paßt. Zumindest der Name GrafikUserInterface-Font scheint diese Idee zu unterstützen. Denn wie gesagt, System_Font ist eher das fette Ding aus 16-Bit-Zeiten.

Gruß Volkmar

[ts-soft]

Hab jetzt GUI-Font und von durch meinen Code ermittelten Font in ein
StringGadget geladen und eine Messagebox aufgerufen.
Die Schrift der Messagebox entspricht exact der, die meine Routine ermittelt.
Die GUI-Font ist dicker und grösser.

[Frabbing]

Bei mir (XP) passt der von Thoma's Code ermittelte Font keineswegs. Es ist der Font für Titelleisten.

Systemfont ist bei mir der ermittelte Ansi-Font per ~ANSI_VAR_FONT. Die API GetStockObject kann übrigens noch weitere Fonts ermitteln wie ~DEVICE_DEFAULT_FONT, vielleicht ist der es ja bei Thomas.

[ts-soft]

MessageFont statt CaptionFont, dann klappts mit dem Nachbarn
Bei mir unter Win7 sind die Fonts aber gleich, deshalb hab ich es nicht
bemerkt.

~ANSI_VAR_FONT sollte total verkehrt sein, seit Win2000 wird durchgehend Unicode in Windows genutzt!

[Volkmar]

Ja, da scheint es mehrere Varianten zu geben. Scheint fast so, daß je nach eingestelltem Schema andere Fonts verwendet werden. Interessant, diese Sache mal näher zu betrachten.

Gruß Volkmar

[Volkmar]

MessageFont sieht gut aus, werde mir die Sache mal merken

Gruß Volkmar

[horsthorn]

Hier noch was:

DEF &WM_SETFONT $30
DEF &DEFAULT_GUI_FONT $011
DEF GetStockObject(1) ! "gdi32","GetStockObject"
'----------------------------------------------
VAR GUIFont& = GetStockObject(&DEFAULT_GUI_FONT)
CLS
VAR button&=CREATE("BUTTON",%hwnd,"ABC abc 123 © ® &",10,10,200,30)
SendMessage(Button&,&WM_SETFONT,GUIFont&,1)
WAITINPUT
END