@db("Create", S1, S2)

cyberangle

Hallo zusammen,
Ich möchte eine DB- Datei mittels @db("Create", S1, S2) erstellen. Die Structurdatei habe ich mit dem entsprechenden Helfer im LemmonED erzeugt.

Code

Declare  erfolg&


erfolg& = @Db("Create", "Einstell.str","Einstell.dbf")


If erfolg&
  Print "Datei erstellt...."
  Print Str$(erfolg&)
Else
  Print "Nicht erstellt!!!"
  Print Str$(erfolg&)
EndIf
WaitKey


erfolg& = @Db("Create", "D:\XProfanX2\Einstell.str","D:\XProfanX2\Einstell1.dbf")


If erfolg&
  Print "Datei erstellt...."
  Print Str$(erfolg&)
Else
  Print "Nicht erstellt!!!"
  Print Str$(erfolg&)
EndIf
WaitKey

Alles anzeigen

Beim 1 Aufruf von DB("create....... Sagt er mir Datei erstellt. Jedoch wurde die Datei nicht erstellt. Auf keiner Partition.

Beim 2. Aufruf sagt er nur
"Ungültige Feldlänge " Zeile 14..................
Wer kann mir weiterhelfen

THFR

Liste hier mal die Einstell.str, damit überprüft werden kann, ob alles den db3-Regeln entspricht und der Helfer sie auch einhält.

Gruß Thomas

cyberangle

Habe festgestellt, das die Structurdatei nach der Erstellung mittels des Datenbankhelfers keine Testdatei ist. Wollte sie dann mittels Profan erstellen.

Code

Declare  erfolg&
Assign #7, "Einstell.str"
  Rewrite #7
    Print #7, "DATEIVZ;    C; 30; 0"
    Print #7, "MWST_KL; N; 6; 2"
    Print #7, "MWST_GR; N; 6; 2"
    Print #7, "ANFBEST; N; 8; 2"
  Close #7
Print FileExists("D:\xprofanx2\Einstell.str")
WaitKey
end

Alles anzeigen

Klappt auch nicht, weder mit #1 noch mit #7.

Habe jetzt die Structurdatei von Hand erstellt. Der Inhalt sieh so aus

Code

DATEIVZ; C; 30; 0
MWST_KL; N; 6; 2
MWST_GR; N; 6; 2
ANFBEST; N; 8; 2

Die Erstellung der Datei klappt aber auch nicht. Ds Ergebnis der Funktion DB("create"....... ist 1 aber es wurde keine Datei erstellt.

ts-soft

Keine Probleme hier, Einstell1.dbf wird mit 162 Bytes erstellt.
Entweder Dir fehlen die Rechte im Ordner, oder aber ein Problem weil Du
die Backslashes nicht verdoppelt hast, was aber nur den Fehler des zweiten
Teils erklären würde. Oder ein Fehler in Deiner Profan-Version.

Getested mit XProfan X2, Editor sollte keine Rolle spielen.

RGH

Hallo,

ich habe es mal getestet!
Folgendes Programm funktioniert völlig korrekt:

Code

Declare  erfolg&
' Strukturdatei erstellen
' -----------------------
Assign #7, "Einstell.str"
  Rewrite #7
    Print #7, "DATEIVZ; C; 30; 0"
    Print #7, "MWST_KL; N; 6; 2"
    Print #7, "MWST_GR; N; 6; 2"
    Print #7, "ANFBEST; N; 8; 2"
  Close #7
erfolg& = FileExists("Einstell.str")
Print "Strukturdatei erzeugt: " + str$(erfolg&)
' Datenbank-Tabelle erstellen
' ---------------------------
erfolg& = @Db("Create", "Einstell.str", "Einstell.dbf")
If erfolg&
  Print "Datei erstellt: " + Str$(erfolg&)
Else
  Print "Nicht erstellt: " + Str$(erfolg&)
EndIf
' Datenbank-Tabelle öffen
' ----------------------
erfolg& = db("Open", #1, "Einstell.dbf")
Print "Tabelle enthält " + str$(erfolg&) + " Sätze!"
db("Close", #1)
WaitInput
End

Alles anzeigen

Natürlich enthält die frisch gebaute Tabelle exakt 0 Sätze! Die Tabelle lässt sich mit dem Helfer "Tabellen bearbeiten" öffnen und zeigt die erwartete Struktur!

Gruß
Roland

Volkmar

Möglicherweise ein Pfadproblem? Ich habe eben mal Dein Beispiel durchlaufen lassen und dabei bei Assign den vollen Pfad angegeben. Und gleich auch noch ein db("Create".. ebenfalls mit vollen Pfaden angehängt, auch die DBase wird korrekt erstellt. Dann das Gleiche nochmal, ein ChDir auf den gewünschten Pfad ganz am Anfang und alle Dateiangaben ohne Pfad, klappt auch problemlos.

Gruß Volkmar

THFR

Roland war schneller. Trotzdem,

Code

Assign #1, $TempDir+ "\\Einstell.STR" 'im TEMP Verzeichnis erstellen und später löschen
Rewrite #1
Print #1, "DATEIVZ; C; 30; 0"
Print #1, "MWST_KL; N; 6; 2"
Print #1, "MWST_GR; N; 6; 2"
Print #1, "ANFBEST; N; 8; 2"
Close #1


db("Create", ($TempDir+ "\\Einstell.STR"), ($TempDir+ "\\Einstell.dbf"))


If FileExists ($TempDir+ "\\Einstell.dbf")
    Messagebox("Die leere DBF-Datei wurde erzeugt.","I N F O",4160)


    else
     Messagebox("Die DBF-Datei konnte nicht erzeugt werden." + \
                 "Das Programm wird beendet!","I N F O",4160)
endif


Assign #1, $TempDir+ "\\Einstell.STR"
case FileExists ($TempDir+ "\\Einstell.STR"): Erase #1  ' TEMP löschen
Close #1


Assign #1, $TempDir+ "\\Einstell.dbf"
case FileExists ($TempDir+ "\\Einstell.dbf"): Erase #1  ' TEMP löschen
Close #1


END

Alles anzeigen

alles mal ins TEMP-Verzeichnis. Ursache könnte vielleicht fehlende Schreibrechte bei W7 sein?

Gruß Thomas

Frank A.

Zitat

Die Structurdatei habe ich mit dem entsprechenden Helfer im LemonEd erzeugt.

LemonEd ruft den Helfer nur auf. Der gehört aber zum XProfan-Paket, hat mit dem Editor aber ansonsten nichts zu tun. Darum spielt der aufrufende Editor auch keine Rolle.

cyberangle

@ Frank,

ich weis, es sollte auch nicht gegen LemmenED gehen.

@ Alle,

Vielen Dank, jetzt läuft alles wie es soll. Ich habe nur am Progammanfang die Pfad mit chdir spezifiziert.

Frank A.

Weiss ich doch, Mike.
Ich wollte es nur richtig erklären, für spätere Einsteiger usw.

Jetzt mitmachen!