Offensichtlich verteil Microsoft sein neues Betriebssystem Windows 10 auch an Windows 7- und 8.1-Anwender, obwohl diese es gar nicht wollen und auch nicht reserviert haben. Unser Moderator Volkmar hat nun ein kleines Tool gebastelt, mit dessen Hilfe man auf sehr einfache Weise das ungewollte Zwangsupgrade auf Windows 10 blockieren kann.
- Nach dem Download genügt ein Doppelklick auf die im Zip-Archiv enthaltene Datei Win10UpgradeBlocker.exe um das Tool zu starten.
[Blockierte Grafik: http://s14.postimg.org/yxxhq8zld/16_09_2015_21_05_12.png]
- Aktiviere nun die Option Upgrade sperren und bestätige dies mit einem Klick auf die Schaltfläche Setzen.
- Soll das Upgrade auf Windows 10 zu einem späteren Zeitpunkt wieder erlaubt werden, starte das Tool erneut und wähle dann die Option Upgrade erlauben.
Das Programm kann hier heruntergeladen werden: https://www.dropbox.com/s/7d8e…10UpgradeBlocker.zip?dl=0
Die Anwendung erfolgt auf eigenes Risiko!
Der Link weist direkt auf den Download der Datei, solltest Du stattdessen auf der Anmeldeseite von DropBox Bussines landen, kopiere bitte einfach diesen Link https://www.dropbox.com/s/7d8e74spy6wbet8/Win10UpgradeBlocker.zip?dl=0 in die Adresszeile Deines Browsers und versuche es erneut.
Ein internes Script der Forensoftware stört manchmal leider ausgehende Links.
Was macht das Tool?
Das Programm erstellt in der Registry im Schlüssel HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate den Eintrag DisableOSUpgrade und weist diesem, je nach Auswahl, folgende Werte zu.
- 0 = Das Upgrade auf Windows 10 ist erlaubt
- 1 = Das Upgrade auf Windows 10 ist gesperrt
Die Anwendung wurde komplett in XProfan geschrieben, der Quelltext steht Jedermann zur Einsicht offen.
$H Windows.PH
Var String RegClass = "HKEY_DW_2"
Var String Regpfad = "SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate"
Var String RegKey = "DisableOSUpgrade"
Var String Link = "www.paules-pc-forum.de"
Var Handle Font = ~GetStockObject(17)
Declare Long Status
Declare Handle CheckOn, CheckOff, BtnSet, BtnLink, Text
WindowStyle 512 + 16 + 8
WindowTitle "Windows 10 Upgradelocker"
Window 320, 128
UseIcon "A"
SetDialogFont Font
CLS ~GetSysColor(15)
CheckOn = Create("RadioButton", %HWnd, "Upgrade auf Win10 erlauben", 4, 4, 160, 16)
CheckOff = Create("RadioButton", %HWnd, "Upgrade auf Win10 sperren", 4, 24, 160, 16)
BtnSet = Create("Button", %HWnd, "Setzen", Width(%HWnd) - 88, Height(%HWnd) - 32, 80, 24)
Text = Create("Text", %HWnd, "", 4, 54, 220, 32)
SetFont Text, 0
Set ("Errorlevel", 0)
UseFont "Arial", 16, 0, 0, 1, 0
TextColor RGB(24, 160, 196), -1
DrawText 180, 4, 180 + 160, 20, "@Volkmar ©2015 für", 0
BtnLink = Control("SysLink","<a href=\qwww.paules-pc-forum.de/\q>Paules-PC-Forum</a>",$50000002,200,28,160,25,%HWnd,9001,%hInstance,0)
Proc ReadStatus
Declare String Msg
Var String RegWert = ReadINI$(RegClass, RegPfad, RegKey)
If %Error
Msg ="Registryeintrag existiert nicht\nDies erlaubt das Upgrade!"
Status = 2
ElseIf RegWert = "0"
Msg = "Upgrade auf Win10 ist erlaubt"
Status = 0
SetCheck CheckOn, 1
ElseIf RegWert = "1"
Msg = "Upgrade auf Win10 ist gesperrt"
Status = 1
SetCheck CheckOff, 1
EndIf
SetText Text, Msg
Return Status
EndProc
Proc SetStatus
Parameters Long Status
WriteINI RegClass, RegPfad, RegKey = Status
Return ReadStatus()
EndProc
Status = ReadStatus()
While 1
EnableWindow BtnSet, GetCheck(CheckOn) Or GetCheck(CheckOff)
WaitInput
If %Key = 2
Break
ElseIf Clicked(BtnSet)
If GetCheck(CheckOn)
SetStatus 0
ElseIf GetCheck(CheckOff)
SetStatus 1
EndIf
ElseIf Clicked(BtnLink)
ShellExec(Link, "open", 1)
EndIf
EndWhile
Oder eben einfach das Tool nutzen, das übernimmt die Arbeit für Euch. 
(unterstützt meine "Faulheit") 